XSLT：从子元素复制属性

Question

输入：

 <a q='r'>
   <b x='1' y='2' z='3'/>
   <!-- other a content -->
 </a>

期望的输出：

 <A q='r' x='1' y='2' z='3'>
   <!-- things derived from other a content, no b -->
 </A>

有人能给我一个食谱吗？

Answer 1

简单的。

<xsl:template match="a">
  <A>
    <xsl:copy-of select="@*|b/@*" />
    <xsl:apply-templates /><!-- optional -->
  </A>
</xsl:template>

如果您没有要处理的 的其他子项，则不需要 。

请注意，

• 使用 将源节点插入到输出中，未更改，
• 使用联合运算符 | 一次选择多个不相关的
• 节点可以将属性节点复制到新元素，只要这是您添加任何子元素之前要做的第一件事。

---

编辑：如果您需要缩小复制的属性以及保留的属性，请使用此（或其变体）：

<xsl:copy-of select="(@*|b/@*)[
  name() = 'q' or name() = 'x' or name() = 'y' or name() = 'z'
]" />

或者甚至

<xsl:copy-of select="(@*|b/@*)[
  contains('|q|x|y|z|', concat('|', name(), '|'))
]" />

注意括号如何使谓词应用于所有匹配的节点。

Answer 2

XSL

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="a">
        <A>
            <xsl:apply-templates select="@*|b/@*|node()"/>
        </A>
    </xsl:template>

    <xsl:template match="b"/>

</xsl:stylesheet>

输出

<A q="r" x="1" y="2" z="3"><!-- other a content --></A>