关于windows批处理文件的奇怪问题

Question

我的工作目录中有 1.txt 和 2.txt 。我使用以下批处理列出所有文件。

批次是这样的：

@echo off
for /f "tokens=*" %%a in ('dir *.txt /b') do (
    echo ---------------
    set file_variable=%%a
    echo file_variable=%file_variable%
    echo filename=%%a
    )    

结果如下：

---------------
file_variable=2.txt   <---------------why it is not 1.txt here??
filename=1.txt
---------------
file_variable=2.txt
filename=2.txt

谢谢。

Answer 1

您需要将：

@setlocal enableextensions enabledelayedexpansion

放在文件的顶部和

endlocal

末尾。

那么就需要使用延迟扩展替换字符。

@setlocal enableextensions enabledelayedexpansion
@echo off
for /f "tokens=*" %%a in ('dir *.txt /b') do (
    echo ---------------
    set file_variable=%%a
    echo file_variable=!file_variable!
    echo filename=%%a
)
endlocal

C:\Documents and Settings\Pax\My Documents> qq.cmd
---------------
file_variable=1.txt
filename=1.txt
---------------
file_variable=2.txt
filename=2.txt

---

在没有延迟扩展的情况下，您所看到的是整个 for 循环在运行之前进行评估。这包括替换，以便 %file_variable% 将被替换为循环开始之前保存的值。使用延迟扩展可以推迟评估，直到执行实际的行。

---

Rob van der Woude 的网站 上有各种精彩的 Windows 脚本技巧，包含很多不同的方法使用各种工具在 Windows 下做事。

Answer 2

在这种特殊情况下，如果您像这样 ECHOed file_variable ，您可以获得正确的输出：

CALL ECHO file_variable=%%file_variable%%

这种方法比 @paxdiablo 的答案。这可能只是延迟变量扩展的一种快速而肮脏的方法，而不需要为此启用特殊语法。