如何将 autodie 与非内置函数一起使用？

Question

autodie 文档暗示，除了默认情况下可以处理的内置函数之外，还可以将它用于其他功能，但没有明确的示例如何在其中执行此操作。

具体来说，我想将它用于成像器模块。其中的许多函数和方法都可能会失败，我希望这不会意味着我的代码将到处都是 或 die Imager|$image->errstr; 短语。

当然，如果除了使用 autodie 之外还有其他方法来实现这一点，我也会对此感兴趣。

Answer 1

autodie 仅适用于函数，不适用于方法。这是因为它是词法作用域的，而方法查找不能是词法作用域的。 autodie::hints 解释了如何告诉 autodie 有关用户定义函数的信息，但是不会对方法做任何事情。

我不知道有什么方法可以让方法获得类似自动死亡的行为，除非模块内置了该行为（例如 DBI 的 RaiseError）。

您可以使用一个子例程来执行检查，但它不会保存那么多代码，因为您仍然必须向其传递正确的对象或类来调用 errstr 。

Answer 2

请参阅 autodie::hints

Answer 3

这是一种与方法一起使用的替代技术：

package SafeCall;
    use Carp ();
    sub AUTOLOAD {
        my ($method) = our $AUTOLOAD =~ /([^:']+)$/;   #'

        unshift @_, my $obj = ${shift @_};

        my $code = $obj->can($method)
            or Carp::croak "no method '$method' on $obj";

        &$code or Carp::croak $obj->can('errstr')
                              ? $obj->errstr
                              : "calling $method on $obj failed"
    }

并使用它：

package Image;
    sub new {bless {here => 'ok', also => 'can be looked up'}};
    sub fails    {$_[0]{not_here}}
    sub succeeds {$_[0]{here}}
    sub lookup   {$_[0]{$_[1]}}
    sub errstr   {'an error occurred'}

package main;
use 5.010; # for say()

my $safe = sub {bless \$_[0] => 'SafeCall'}; 
# storing the constructor in the scalar $safe allows $safe to be used
# as a method:  $obj->$safe->method

my $img = Image->new;

say $img->$safe->succeeds;       # prints 'ok'

say $safe->($img)->succeeds;     # or call this way (also prints 'ok')

say $img->$safe->lookup('also'); # prints 'can be looked up'

say $img->$safe->fails;      # dies with 'an error occurred at file.pl line ##'