使用来自其他 Cython 代码的自定义 Cython 代码

Question

我目前正在尝试优化我的 Python 程序，并开始使用 Cython 以减少函数调用开销，也许稍后会包含优化的 C 库函数。

所以我遇到了第一个问题：

我在代码中使用组合来创建一个更大的类。到目前为止，我已经将我的一个 Python 类转换为 Cython（这已经足够困难了）。代码如下：

import numpy as np
cimport numpy as np
ctypedef np.float64_t dtype_t
ctypedef np.complex128_t cplxtype_t
ctypedef Py_ssize_t index_t

cdef class bendingForcesClass(object):
    cdef dtype_t bendingRigidity
    cdef np.ndarray matrixPrefactor
    cdef np.ndarray bendingForces

    def __init__(self, dtype_t bendingRigidity, np.ndarray[dtype_t, ndim=2] waveNumbersNorm):
        self.bendingRigidity = bendingRigidity
        self.matrixPrefactor = -self.bendingRigidity * waveNumbersNorm ** 2

    cpdef np.ndarray calculate(self, np.ndarray membraneHeight):
        cdef np.ndarray bendingForces
        bendingForces = self.matrixPrefactor * membraneHeight
        return bendingForces

在我的组合 Python/Cython 类中，我调用类方法 calculate，因此在我的组合类中，我有以下（简化的）代码：

from bendingForcesClass import bendingForcesClass

cdef class membraneClass(object):
    def  __init__(self, systemSideLength, lowerCutoffLength, bendingRigidity):
        self.bendingForces = bendingForcesClass(bendingRigidity, self.waveNumbers.norm)

    def calculateForces(self, heightR):
        return self.bendingForces.calculate(heightR)

我发现 cpdef 使方法/函数可以从 Python 和 Cython 调用，这很棒并且有效，只要我不尝试事先定义 self.bendingForces 的类型 - 根据为了消除函数调用开销，文档（早期绑定速度）是必要的。我尝试了以下方法，但不起作用：

from bendingForcesClass import bendingForcesClass
from bendingForcesClass cimport bendingForcesClass

    cdef class membraneClass(object):
        cdef bendingForcesClass bendingForces

        def  __init__(self, systemSideLength, lowerCutoffLength, bendingRigidity):
            self.bendingForces = bendingForcesClass(bendingRigidity, self.waveNumbers.norm)

        def calculateForces(self, heightR):
            return self.bendingForces.calculate(heightR)

在尝试使用 Cython 构建 membraneClass.pyx 时，我收到此错误：

membraneClass.pyx:18:6: 'bendingForcesClass' is not a type identifier
building 'membraneClass' extension

请注意，声明位于两个单独的文件中，这使得这变得更加困难。

那么我该如何完成这件事呢？如果有人能给我指点，我将非常感激，因为除了上面给出的链接之外，我找不到任何有关此的信息。

谢谢并致以诚挚的问候！

Answer 1

免责声明：这个问题很老了，我不确定当前的解决方案是否适用于 2011 Cython 代码。

为了从另一个文件导入扩展类（cdef 类），您需要提供 .pxd 文件（也称为定义文件）声明所有 C 类、属性和方法。请参阅文档中的共享扩展类型供参考。

对于您的示例，您需要一个文件 bendingForcesClass.pxd，它声明您想要共享的类，以及所有 cimport、模块级变量、typedef 等：

bendingForcesClass .pxd

# cimports
cimport numpy as np

# typedefy you want to share
ctypedef np.float64_t dtype_t
ctypedef np.complex128_t cplxtype_t
ctypedef Py_ssize_t index_t

cdef class bendingForcesClass:
    # declare C attributes
    cdef dtype_t bendingRigidity
    cdef np.ndarray matrixPrefactor
    cdef np.ndarray bendingForces

    # declare C functions
    cpdef np.ndarray calculate(self, np.ndarray membraneHeight)

    # note that __init__ is missing, it is not a C (cdef) function

所有导入、变量和现在在 .pxd 文件中声明的属性可以（并且必须）从 .pyx 文件中删除：

bendingForcesClass .pyx

import numpy as np

cdef class bendingForcesClass(object):

    def __init__(self, dtype_t bendingRigidity, np.ndarray[dtype_t, ndim=2] waveNumbersNorm):
        self.bendingRigidity = bendingRigidity
        self.matrixPrefactor = -self.bendingRigidity * waveNumbersNorm ** 2

    cpdef np.ndarray calculate(self, np.ndarray membraneHeight):
        cdef np.ndarray bendingForces
        bendingForces = self.matrixPrefactor * membraneHeight
        return bendingForces

现在您的 cdef 类 bendingForcesClass可以从其他 Cython 模块导入，使其成为有效的类型标识符，这应该可以解决您的问题。

Answer 2

您需要使用声明“.pxd”文件和 cimport。 （本质上，cimport 发生在编译时，而 import 发生在运行时，因此 Cython 无法利用任何重要的内容）。

创建“utils.pxd”：

cdef class MyClass:
    cdef readonly int field
    cdef void go(self, int i)

“utils.pyx”现在读取

cdef class MyClass:
    def __init__(self, field):
    self.field = field

cdef void go(self, int i):
    self.field = i

pyx 文件中的所有声明读取到 .pxd 文件中。

然后在mymodule.pyx中

from utils import MyClass
from utils cimport MyClass
# other code follows...

// 这里的扩展答案：
Cython：在类型声明中使用导入的类

Answer 3

这些可能不是错误的根源，但为了缩小问题范围，您可以尝试更改以下内容：

是否您在此处使用 bendingForces 作为变量的名称：

cpdef np.ndarray calculate( self, np.ndarray membraneHeight ) :
      cdef np.ndarray bendingForces
      bendingForces = self.matrixPrefactor * membraneHeight
      return bendingForces

以及也是此处成员对象的名称：

cdef class membraneClass( object ):
    cdef bendingForcesClass bendingForces

此外，bendingForcesClass 是模块和类的名称。最后，从类 bendingForcesClass 中创建一个 ctypedef 怎么样？