如何在 XSL 中迭代多节点结构

Question

我需要迭代多节点结构，但该结构仅由前导节点标识，并且该前导节点后面的节点可能会有所不同。

在此示例中，我需要迭代每个

XML 文件：

<books>
    <title>book_one</title>
    <price>price_for_book_one</price>
    <notes>notes_for_book_one</notes>

    <title>book_two</title>
    <price>price_for_book_two</price>
</books>

所需的输出：

<div class="book">
    <h1 id="title">book_one</h1>
    <h2 id="values">
        <p>price_for_book_one</p>
        <p>notes_for_book_one</p>
    </h2>
</div>

<div class="book">
    <h1 id="title">book_two</h1>
    <h2 id="values">
        <p>price_for_book_two</p>
    </h2>
</div>

我的尝试：

<xsl:template match="/">
    <xsl:for-each select="books/title">
        <h1 id="title"><xsl:text>Title:</xsl:text>
            <xsl:value-of select="." />
        </h1>

        <h2 id="values">    
        <!-- have other templates for matching all possible following-sibling nodes -->
            <xsl:apply-templates select="following-sibling::*>
        </h2>
    </xsl:for-each>
</xsl:template>

但这只是选择标题节点而不解析任何其他节点，因为“books/title”仅选择标题节点。

注意： 和 是两个示例节点，

任何想法将不胜感激。

Answer 1

在循环内，上下文节点是 title，因此使用 . 选择它。

您可能只需要标题后面的第一个价格和注释元素。我还使用 xsl:text 来减少每个段落中的空白。

<xsl:template match="/">
    <xsl:for-each select="books/title">
        <p>
            <xsl:text>Title: </xsl:text>
            <xsl:value-of select="." />
        </p>
        <p>
            <xsl:text>Price: </xsl:text>
            <xsl:value-of select="following-sibling::price[1]"/>
        </p>
        <p>
            <xsl:text>Notes: </xsl:text>
            <xsl:value-of select="following-sibling::notes[1]"/>
        </p>
    </xsl:for-each>
</xsl:template>

如果每个 title 之间的附加节点不固定，您可以使用模板来处理每个节点。这里重要的是用于选择属于当前标题的非标题元素的 XPath 表达式。

<xsl:template match="/">
    <xsl:for-each select="books/title">
        <p>
            <xsl:text>Title:</xsl:text>
            <xsl:value-of select="." />
        </p>
        <xsl:apply-templates select="following-sibling::*[
                                       local-name() != 'title' and
                                       preceding-sibling::title[1] = current()]"/>
    </xsl:for-each>
</xsl:template>

<xsl:template match="price">
    <p>
        <xsl:text>Price: </xsl:text>
        <xsl:value-of select="."/>
    </p>
</xsl:template>

Answer 2

首先，您似乎不需要分组。 时，才需要此样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="books/*">
        <p>
            <xsl:value-of
                 select="concat(translate(
                                   substring(local-name(),1,1),
                                   'qwertyuiopasdfghjklzxcvbnm',
                                   'QWERTYUIOPASDFGHJKLZXCVBNM'
                                ),
                               substring(local-name(),2),
                                ': ',
                                .
                         )" />
        </p>
    </xsl:template>
</xsl:stylesheet> 

输出：分组

<p>Title: book_one</p>
<p>Price: price_for_book_one</p>
<p>Notes: notes_for_book_one</p>
<p>Title: book_two</p>
<p>Price: price_for_book_two</p>

仅当您要对组执行某些操作（例如换行：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="kElementByPrecedingTitle"
             match="books/*"
             use="generate-id((.|preceding-sibling::*)[self::title][last()])"/>
    <xsl:template match="books/*">
        <p>
            <xsl:value-of
                 select="concat(translate(
                                   substring(local-name(),1,1),
                                   'qwertyuiopasdfghjklzxcvbnm',
                                   'QWERTYUIOPASDFGHJKLZXCVBNM'
                                ),
                               substring(local-name(),2),
                                ': ',
                                .
                         )" />
        </p>
    </xsl:template>
    <xsl:template match="books">
        <xsl:for-each select="title">
            <div class="book">
                <xsl:apply-templates
                 select="key('kElementByPrecedingTitle',generate-id())"/>
            </div>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

输出：）

<div class="book">
    <p>Title: book_one</p>
    <p>Price: price_for_book_one</p>
    <p>Notes: notes_for_book_one</p>
</div>
<div class="book">
    <p>Title: book_two</p>
    <p>Price: price_for_book_two</p>
</div>