可区分联合中类型之间的转换

Question

我有一个函数，它可以返回不同的类型，并且我使用可区分联合来实现此目的。我需要的是从可区分联合中的一种类型转换为另一种类型。 此外，某些类型可以转换为所有其他类型 (String)，但某些类型只能转换为 String (MyCustomType)

为此，我添加了ConvertTo 到 ResultType 的成员方法：

type MyTypes = 
   | Boolean       = 1
   | Integer       = 2
   | Decimal       = 3
   | Double        = 4
   | String        = 5
   | MyCustomType  = 6

type ResultType = 
   | Boolean of bool
   | Integer of int
   | Decimal of decimal
   | Double of double
   | String of string
   | MyCustomType of MyCustomType

   with 
     member this.ConvertTo(newType: MyTypes) = 
       match this with 
       | ResultType.Boolean(value) -> 
           match newType with 
           | MyTypes.Boolean -> 
              this
           | MyTypes.Integer -> 
              ResultType.Integer(if value then 1 else 0)
          ...
       | ResultType.MyCustomType(value) -> 
           match newType with 
           | MyTypes.MyCustomType -> 
              this
           | MyTypes.String -> 
              ResultType.String(value.ToString()) 
           | _ -> 
              failwithf "Conversion from MyCustomType to %s is not supported" (newType.ToString())

我不喜欢这样的构造，因为如果我添加更多类型，这需要我做很多更改：MyTypes、ResultType 以及 ConvertTo 成员函数中的多个位置。

任何人都可以为此类类型转换提出更好的解决方案吗？

提前致谢

Answer 1

通过稍微不同的设计，可以利用 System.Convert.ChangeType 以及可区分联合的构造函数实际上是函数的事实：

// statically typed wrapper for System.Convert.ChangeType
let conv a : 'T = System.Convert.ChangeType(a, typeof<'T>) :?> 'T

type MyCustomType() = class end

type ResultType = 
  | Boolean of bool
  | Integer of int
  | Decimal of decimal
  | Double of double
  | String of string
  | MyCustomType of MyCustomType
  with
    member this.ConvertTo (newType:'T->ResultType) =
      match this with
      | Boolean b -> newType( conv b )
      | Integer i -> newType( conv i )
      | Decimal d -> newType( conv d )
      | Double d -> newType( conv d )
      | String s -> newType( conv s )
      | MyCustomType m ->
         if typeof<'T> <> typeof<string> then
            raise (new System.InvalidCastException("MyCustomType can only be converted to String"))
         else
            String (m.ToString())

let i = Integer 42

let b = i.ConvertTo Boolean
printfn "%A" b

let d = i.ConvertTo Decimal
printfn "%A" d

let d2 = i.ConvertTo Double
printfn "%A" d2

let s = i.ConvertTo String
printfn "%A" s

//let mi = i.ConvertTo MyCustomType  // throws InvalidCastException

let m = MyCustomType (new MyCustomType())
let sm = m.ConvertTo String
printfn "%A" sm

//let im = m.ConvertTo Integer // throws InvalidCastException

编辑：一旦添加更多自定义类型，这不会有太大帮助。

也许您应该让您的自定义类型实现IConvertible。然后，您可以从 ConvertTo 中删除特殊情况代码，并完全依赖 System.Convert.ChangeType。

每当添加新的自定义类型时，您仍然需要扩展每个自定义类型的 ToObject 实现。这是否真的比中央 ConvertTo 函数更好是有争议的。

Answer 2

为什么要首先进行类型转换？可区分联合是隐藏类型信息直到您需要它并抽象复杂性的好方法。通常，您在使用此类型的函数中有一个匹配语句，然后仅在需要时才进行强制转换。

如果您尝试制作某种类型的解析器或语言引擎，那么您别无选择，只能定义所有转换或至少定义它们的错误状态。如果您不介意详细说明为什么/要使用它做什么，也许我可以建议另一种方法。

顺便说一句：F# 和 .NET 通常不支持返回类型的重载。