monad 转换器中的内部 monad 是否有 `replicateM` 函数？

Question

假设我有这样的东西：

data Environment = ...
data MyState = ...
data Report  = ...

updateState :: Environment -> MyState -> MyState
updateState = ...

report :: MyState -> Report
report = ...

foo :: ReaderT Environment (State MyState) Report 
foo = do env   <- ask
         state <- lift get
         let newState = updateState env state
         lift $ put newState
         return $ report newState

我脑子里是对时间过程的模拟，其中我有将存储在Environment中的参数，动态状态将存储在MyState中> 我希望在模拟的每个时间步中收集的信息将存储在报告中。

现在，我不想运行此模拟的许多步骤并获取包含每个时间步骤的报告的列表。

我通常在没有 ReaderT 的情况下执行此操作，并用于传递如下参数：

 foo :: Enviroment -> State MyState Report

然后我会这样做：

 manySteps :: Int -> Enviroment -> State MyState [Report]
 manySteps n env = replicate n $ (foo env) 

我对 lift 和 的类型感到困惑复制M。是否有一个组合可以在变压器内复制 State MyState monad？

将来我会将 ReaderT Environment (State MyState) Report 替换为 ReaderT Environment (StateT MyState (Rand StdGen)) Report，因此最好在执行此操作之前先把事情做好怪物类型:(。

编辑：作为一个附带问题-是否有比使用ReaderT环境（State MyState）报告更好的策略？

Answer 1

这里有一个replicateM的具体例子：

import Control.Monad
import Control.Monad.Reader
import Control.Monad.State

data Environment = E Int deriving Show
data MyState = S Int deriving Show
data Report  = R String deriving Show

updateState :: Environment -> MyState -> MyState
updateState (E step) (S val) = S $! val + step

report :: MyState -> Report
report (S val) = R (show val)

foo :: ReaderT Environment (State MyState) Report 
foo = do env   <- ask
         state <- get -- lift was not needed
         let newState = updateState env state
         put newState -- lift was not needed
         return $ report newState

run e s m = runState (runReaderT m e) s

请注意，我删除了“lift”，因为ReaderT有一个MonadState传递实例。运行 foo 一次给出：

*Main> run (E 10) (S 5) foo
(R "15",S 15)

我可以连续运行 foo 七次：

*Main> run (E 10) (S 5) (replicateM 7 foo)
([R "15",R "25",R "35",R "45",R "55",R "65",R "75"],S 75)

上面的内容需要更多说明吗？

Answer 2

有时，如果您不确定如何使用

-- import Control.Monad.State
import Control.Monad
import Control.Monad.Trans.Reader

data Environment
data MyState
data Report
data State a b
instance Monad (State a)

foo = undefined :: ReaderT Environment (State MyState) Report

GHCi 中的某些内容，那么证明类型就足够了

*Main> :t flip replicateM foo
flip replicateM foo
  :: Int -> ReaderT Environment (State MyState) [Report]