如何使用 awk 在文件中的模式后打印 5 个连续行

Question

我想在文件中搜索模式并在找到该模式后打印 5 行。

我需要使用 awk 才能执行此操作。

示例：

文件内容：

.
.
.
.
####PATTERN#######
#Line1
#Line2
#Line3
#Line4
#Line5
.
.
.

如何解析文件并仅打印上述行？ 我是否使用包含“PATTERN”的行的 NR 并保持递增到 5 并打印过程中的每一行。 请让我知道是否有其他有效的方法可以在 Awk 中完成此操作。

Answer 1

在 AWK 中执行此操作的另一种方法：

awk '/PATTERN/ {for(i=1; i<=5; i++) {getline; print}}' inputfile

在 sed 中：

sed -n '/PATTERN/{n;p;n;p;n;p;n;p;n;p}' inputfile

在 GNU sed 中：

sed -n '/PATTERN/,+7p' inputfile

或

sed -n '1{x;s/.*/####/;x};/PATTERN/{:a;n;p;x;s/.//;ta;q}' inputfile

# 字符代表计数器。使用比要输出的行数少一行的行。

Answer 2

awk '
{ 
    if (lines > 0) {
        print;
        --lines;
    }
}

/PATTERN/ {
    lines = 5
}

' < input

这产生：

#Line1
#Line2
#Line3
#Line4
#Line5

Answer 3

如果决定给 grep 一个机会，grep "PATTERN" search-file -A 5 将为您完成这项工作。

编辑：您也可以从 awk 脚本内部使用 system() 函数调用 grep。

Answer 4

awk 来救援！

打印图案行（共 6 行）

$ awk '/^####PATTERN/{c=6} c&&c--' file

####PATTERN#######
#Line1
#Line2
#Line3
#Line4
#Line5

跳过图案并打印接下来的五行

$ awk 'c&&c--; /^####PATTERN/{c=5}' file

#Line1
#Line2
#Line3
#Line4
#Line5

Answer 5

编辑：没有注意到PATTERN不应该是输出的一部分。

cat /etc/passwd | awk '{if(a-->0){print;next}} /qmaild/{a=5}'

或者

cat /etc/passwd | awk ' found && NR-6 < a{print} /qmaild/{a=NR;found=1}'

我能想到的最短的是：

cat /etc/passwd | awk 'a-->0;/qmaild/{a=5}'

读为a趋于0。/qmaild/将a设置为5:-)

Answer 6

快速而肮脏的解决方案：awk '/PATTERN/ {i=0} { if (i<=5) {print $0}; i+=1} 开始 {i=6}'

Answer 7

与 Johnsyweb 的解决方案一样有限，但使用不同的方法和 GNU awk 的高级功能，允许完整的 RegEx 记录分隔符，从而产生一段代码，恕我直言，非常 awk - ish：

awk -F\\\n '{NF=5}NR-1' RS="PATTERN[^\n]*." OFS=\\\n

因此，如果您想要一个稳定且可读的解决方案，请遵循 Dennis Williamson 的答案（+1），但也许您在查看这样的行时也只是享受 awk 的美丽。