我需要一个 XSL 样式表，它允许我移动 XML 元素以在前一个同级元素的最后一个元素之前进行打印

Question

拜托，我需要你的帮助！

我需要一个 XSL 样式表，它允许我移动 XML 元素以在前一个同级元素的最后一个元素（或它可能是）之前打印。我的 if 语句是：

IF（<工具> 或 <零件>）和 <计划>存在于 XML 中，那么 MOVE <计划>打印之前（<工具> 或 <零件>） 否则只需<应用模板/>。

我已经尝试了几件事，但在之前我无法打印它。或者在某些文件中，它是。

XML 如下：

<work>
    <prelim>
        <code>ABC</code>
        <source>DEF</source>
        <tools>Includes codes for a table</tools>
    </prelim>
    <main>
        <planning>Text for Planning</planning>
        <p>blah blah blah</p>
    </main>
</work>

如果上述条件存在，我希望我的输出为：

<work>
    <prelim>
        <code>ABC</code>
        <source>DEF</source>
        <planning>Text for Planning</planning>
        <tools>Includes codes for a table</tools>
    </prelim>
    <main>
        <p>blah blah blah</p>
    </main>
</work>

任何人都可以帮助我实现这一目标吗？

提前致谢！！

琳达

Answer 1

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="tools[not(preceding-sibling::parts)]|
                         parts[not(preceding-sibling::tools)]">
        <xsl:for-each select="../../main/planning">
            <xsl:call-template name="identity"/>
        </xsl:for-each>
        <xsl:call-template name="identity"/>
    </xsl:template>
    <xsl:template match="planning"/>
</xsl:stylesheet>

输出：

<work>
    <prelim>
        <code>ABC</code>
        <source>DEF</source>
        <planning>Text for Planning</planning>
        <tools>Includes codes for a table</tools>
    </prelim>
    <main>
        <p>blah blah blah</p>
    </main>
</work>

其他模式的方法：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="node()|@*" name="identity">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="tools[not(preceding-sibling::parts)]|
                         parts[not(preceding-sibling::tools)]">
        <xsl:apply-templates select="../../main/planning" mode="copy"/>
        <xsl:call-template name="identity"/>
    </xsl:template>
    <xsl:template match="planning"/>
    <xsl:template match="node()|@*" mode="copy">
        <xsl:call-template name="identity"/>
    </xsl:template>
</xsl:stylesheet>

Answer 2

此转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="node()|@*" name="identity">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>
 <xsl:template match=
 "/*/*[1]/*[not(self::tools or self::parts)]
             [not(preceding-sibling::*[self::tools or self::parts])]
                                         [last()]">
  <xsl:call-template name="identity"/>
  <xsl:copy-of select="../following-sibling::*[1]/planning"/>
 </xsl:template>
 <xsl:template match="planning"/>
</xsl:stylesheet>

当应用于提供的 XML 文档时：

<work>
    <prelim>
        <code>ABC</code>
        <source>DEF</source>
        <tools>Includes codes for a table</tools>
    </prelim>
    <main>
        <planning>Text for Planning</planning>
        <p>blah blah blah</p>
    </main>
</work>

准确产生所需的正确结果：

<work>
   <prelim>
      <code>ABC</code>
      <source>DEF</source>
      <planning>Text for Planning</planning>
      <tools>Includes codes for a table</tools>
   </prelim>
   <main>
      <p>blah blah blah</p>
   </main>
</work>

说明：

1. < p>身份规则（模板）“按原样”复制每个节点。

2. 两个模板覆盖身份规则 - 一个用于防止规划的“就地复制”，另一个用于执行实际的移动操作。

3. 执行移动操作的覆盖模板具有以下属性：

   它匹配满足以下条件的任何元素：1) 是顶部元素的第一个子元素的子元素，2) 不是 tool 或 parts，并且 3)前面没有 tool 或 parts 的同级元素，并且 4) 是满足 1)、2) 和 3) 的任何元素中的最后一个。

   操作很简单：该模板通过按名称调用身份规则来复制当前节点。然后，它复制其“表兄弟”——其父元素的第一个同级元素的 planning child`。