Delphi：计算一个字符串在另一个字符串中出现的次数

Question

我正在使用 Delphi 2007，想知道是否有一种简单的方法来计算一个字符串在另一个字符串中出现的次数。我可以使用任何内置函数吗？

示例：

• “How”在字符串“How are you?”中出现一次。
• “do”在字符串“How do you do?”中出现两次

Answer 1

function Occurrences(const Substring, Text: string): integer;
var
  offset: integer;
begin
  result := 0;
  offset := PosEx(Substring, Text, 1);
  while offset <> 0 do
  begin
    inc(result);
    offset := PosEx(Substring, Text, offset + length(Substring));
  end;
end;

Answer 2

我见过的最聪明的方法之一：

{ Returns a count of the number of occurences of SubText in Text }
function CountOccurences( const SubText: string;
                          const Text: string): Integer;
begin
  if (SubText = '') OR (Text = '') OR (Pos(SubText, Text) = 0) then
    Result := 0
  else
    Result := (Length(Text) - Length(StringReplace(Text, SubText, '', [rfReplaceAll]))) div  Length(subtext);
end;  { CountOccurences }

Answer 3

如果您发现自己经常在大量文本中搜索出现的内容并且性能成为问题，您可以尝试Boyer-Moore 搜索算法。

查找所有出现的最坏情况
一篇文本大约需要 3n
比较

Delphi 中的实现可以在我们自己的 SO 此处

我需要三个快速大弦
功能：快速搜索、快速搜索
并替换，并快速计数
字符串中的子字符串。

Answer 4

较新的 Delphi 版本有一个 CountChar< /a> 字符串助手，计算字符串中单个字符的出现次数：

var
  MyText: String;
begin
  MyText := 'How are you?';
  ShowMessage(MyText.CountChar('o').ToString);
end;

Answer 5

function stringcount(pBefore: String; pSubstring: String; pFlags: TReplaceFlags): Integer;
begin
  result:= round((pBefore.Length - stringreplace(pBefore, pSubstring, '', pFlags).Length) / pSubstring.Length);
end;

Answer 6

uses
  StrUtils;    

function Occurrences(const Substring, Text: string;
  const ignoreUppercase: Boolean = false): Integer;
var
  inSubstring, inText: string;
  inPos: Integer;
begin
  Result:= 0;

  if (Substring = '') or (Text = '') then
    Exit;

  if ignoreUppercase then
  begin
    inSubstring:= AnsiLowerCase(Substring);
    inText:=  AnsiLowerCase(Text);
  end
  else
  begin
    inSubstring:= Substring;
    inText:=  Text;
  end;

  inPos:= 1;

  repeat
    inPos:= posEx(inSubstring, inText, inPos);
    if inPos > 0 then
    begin
      Inc(Result);
      inPos:= inPos + Length(inSubstring);
    end;
  until inPos = 0;
end;