如何使用 XSLT 为给定属性的每个值选择第一个节点？

Question

我有一个如下所示的文档：

<template>
 <otherstuff>
 <group name="foo">
 ...stuff...
 </group>
</template>
<template>
 <otherstuff>
 <group name="bar">
 ...different stuff...
 </group>
</template>
<template>
 <otherstuff>
 <group name="foo">
 ...same stuff as first foo group...
 </group>
</template>

我想要做的是为给定组名的每个实例调用特定模板 - 因此一次为“foo”，一次为“bar”。由于它们是相同的，所以我不在乎使用它们中的哪一个来调用此模板。

按照的答案选择基于两个属性值的组合，我生成了以下代码：

<xsl:key name="groupsByName" match="//group" use="@name"/>

<xsl:template match="/">
    <xsl:for-each select="//group[count(.|key('groupsByName',@name)[1])!=1]">
        <xsl:call-template name="template-or-group"/>
    </xsl:for-each>
</xsl:template>

但是，结果是未调用模板。我还怀疑，由于我的案例比我基于代码的问题更简单，因此可能有一种更简单的方法。不过，我的 XSLT 还不够强大，无法弄清楚它可能是什么。

Answer 1

我建议将您的模板替换为：

<xsl:template match="group[generate-id(.) = generate-id(key('groupsByName',@name)[1])]">
  ....
</xsl:template>

或者将您的 xpath 表达式更改为 //group[generate-id(.) =generate-id(key('groupsByName',@name)[1])].

count(.|some-node-set) 通常用于检查某个节点是否属于集合。在这里，您需要将当前节点与每个组的第一个唯一节点进行比较。此外，改进 Xpath 表达式并仅匹配那些具有 @name 属性的组元素也可能很有用。说了这么多，我们得到：//group[@name][generate-id(.) =generate-id(key('groupsByName', @name)[1])]。

Answer 2

只需替换：

//group[count(.|key('groupsByName',@name)[1])!=1]

为：

//group[count(.|key('groupsByName',@name)[1])=1]

这是一个完整的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="groupsByName" match="//group"
      use="@name"/>

 <xsl:template match="/">
  <xsl:for-each select=
   "//group[count(.|key('groupsByName',@name)[1])=1]">
   <xsl:call-template name="template-or-group"/>
  </xsl:for-each>
 </xsl:template>

 <xsl:template name="template-or-group">
  <xsl:value-of select="@name"/>
  <xsl:text>
</xsl:text>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时（固定为良好） -形成）：

<t>
    <template>
        <otherstuff/>
        <group name="foo">  ...stuff...  </group>
    </template>
    <template>
        <otherstuff/>
        <group name="bar">  ...different stuff...  </group>
    </template>
    <template>
        <otherstuff/>
        <group name="foo">  ...same stuff as first foo group...  </group>
    </template>
</t>

产生了想要的正确结果：

foo
bar