.NET 接口上的静态构造函数未运行

Question

您可以在 IL 中的 .NET 接口上定义静态构造函数。但是，如果这样做，当您在接口上运行方法时，静态构造函数不会运行：

.method public static void Main() {
    .entrypoint    
    .locals init ( class IInterface cls1 )

    // InterfaceClass static constructor is run
    newobj instance void InterfaceClass::.ctor()
    stloc.0
    ldloc.0
    // IInterface static constructor is not run!!!!!
    callvirt instance int32 IInterface::Method()
    call void [mscorlib]System.Console::WriteLine(int32)
    ret
}

.class public interface IInterface {
    .method private static specialname rtspecialname void .cctor() {
        ldstr "Interface static cctor"
        call void [mscorlib]System.Console::WriteLine(string)
        ret
    }

    .method public abstract virtual instance int32 Method() {}
}

.class public InterfaceClass implements IInterface {

    .method private static specialname rtspecialname void .cctor() {
        ldstr "Class static cctor"
        call void [mscorlib]System.Console::WriteLine(string)
        ret
    }

    .method public specialname rtspecialname instance void .ctor() {
        ldarg.0
        call instance void [mscorlib]System.Object::.ctor()
        ret
    }

    .method public virtual instance int32 Method() {
        ldc.i4.s 42
        ret
    }
}

这是怎么回事？ CLR 规范（分区 II，10.5.3.1）表示，类型初始值设定项何时执行是在分区 I 中指定的，但我在分区 I 中找不到任何对类型初始值设定项执行的引用。

编辑：

我可以运行接口静态初始化程序，但只能通过向接口添加静态字段并在代码中的某处访问该字段，即使该字段实际上并未在静态构造函数。因此，似乎在接口上调用方法不会使静态构造函数运行，但访问字段却可以。为什么会这样呢？规范中哪里提到了这一点？

Answer 1

在我看来，即使您可以在 CLI 中的接口上定义 .cctor，它也是无用的。第 I 部分第 8.9.5 条规定：

如果标记为 BeforeFieldInit，则在首次访问为该类型定义的任何静态字段时或之前执行该类型的初始化方法。如果未标记 BeforeFieldInit，则该类型的初始化方法将在以下位置执行（即触发）：
首先访问该类型的任何静态字段，或者
第一次调用该类型的任何静态方法，或者
第一次调用该类型的任何实例或虚拟方法（如果它是值类型）或
第一次调用该类型的任何构造函数。
执行任何类型的初始化方法都不会触发其基类型定义的任何初始化方法的自动执行，也不会触发该类型实现的任何接口的自动执行

（强调我的）这意味着接口上的类型初始值设定项不会触发完全被自动调用。如果您希望调用它，您（恕我直言）需要在所有实现类中显式调用它，如下所示：

.method private static specialname rtspecialname void .cctor() {
    ldtoken IInterface
    callvirt instance valuetype [mscorlib]System.RuntimeTypeHandle [mscorlib]System.Type::get_TypeHandle()
    call void [mscorlib]System.Runtime.CompilerServices.RuntimeHelpers::RunClassConstructor(valuetype [mscorlib]System.RuntimeTypeHandle)
    ldstr "Class static cctor"
    call void [mscorlib]System.Console::WriteLine(string)
    ret
}