如何在XSLT 1.0中实现SPLIT功能

Question

我有以下场景。我有一个 TEAM-MEMBERS 节点，其名称格式为“姓氏，名字”，

<TEAM-MEMBER><LONG-NAME>Last Name, First Name</LONG-NAME></TEAM-MEMBER>

我想将其转换为

<CONTACT><FIRSTNAME>First Name</FIRSTNAME><LASTNAME>Last Name</LASTNAME></CONTACT>

基本上我想按 拆分 节点的值，

我如何使用 XSLT 1.0 实现此目的

此 XSLT 将由 BizTalk Server 使用，因此我只寻找一些 XSLT 1.0 解决方案

谢谢

Karthik

Answer 1

这是一个完整的 XSLT 1.0 解决方案，它使用通用的“拆分”模板，将字符串拆分为多个子字符串，并提供分隔符来指定子字符串之间的边界：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="TEAM-MEMBER">
  <xsl:variable name="vrtfSplitWords">
   <xsl:call-template name="split">
    <xsl:with-param name="pText" select="."/>
   </xsl:call-template>
  </xsl:variable>

  <xsl:variable name="vSplitWords"
  select="ext:node-set($vrtfSplitWords)/*"/>

  <CONTACT>
   <FIRSTNAME><xsl:value-of select="$vSplitWords[2]"/></FIRSTNAME>
   <LASTNAME><xsl:value-of select="$vSplitWords[1]"/></LASTNAME>
  </CONTACT>
 </xsl:template>

 <xsl:template name="split">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pDelim" select="', '"/>
  <xsl:param name="pElemName" select="'word'"/>

  <xsl:if test="string-length($pText)">
   <xsl:element name="{$pElemName}">
    <xsl:value-of select=
     "substring-before(concat($pText,$pDelim),
                       $pDelim
                      )
     "/>
   </xsl:element>

   <xsl:call-template name="split">
    <xsl:with-param name="pText" select=
    "substring-after($pText,$pDelim)"/>
    <xsl:with-param name="pDelim" select="$pDelim"/>
    <xsl:with-param name="pElemName" select="$pElemName"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档：

<TEAM-MEMBER><LONG-NAME>Last Name, First Name</LONG-NAME></TEAM-MEMBER>

生成所需的正确结果：

<CONTACT>
   <FIRSTNAME>First Name</FIRSTNAME>
   <LASTNAME>Last Name</LASTNAME>
</CONTACT>

II．使用 FXSL 的解决方案

此转换使用 FXSL 中的 str-split-to-words 模板：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext"
>
  <xsl:import href="strSplit-to-Words.xsl"/>
  <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:strip-space elements="*"/>
   <xsl:output indent="yes" omit-xml-declaration="yes"/>

   <xsl:param name="pmaxLines" select="10"/>

    <xsl:template match="/">
      <xsl:variable name="vwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters"
                          select="',()'"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:apply-templates select=
       "ext:node-set($vwordNodes)/*[normalize-space()]"/>

    </xsl:template>

    <xsl:template match="word[normalize-space()][1]">
      <FIRSTNAME>
       <xsl:value-of select="normalize-space()"/>
      </FIRSTNAME>
    </xsl:template>

    <xsl:template match="word[normalize-space()][2]">
      <MIDNAME>
       <xsl:value-of select="normalize-space()"/>
      </MIDNAME>
    </xsl:template>

    <xsl:template match="word[normalize-space()][last()]">
      <LASTNAME>
       <xsl:value-of select="normalize-space(.)"/>
      </LASTNAME>
    </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时（变得更加复杂）：

<TEAM-MEMBER><LONG-NAME>First Name, (Jr.), Last Name</LONG-NAME></TEAM-MEMBER>

< strong>生成了想要的正确结果：

<FIRSTNAME>First Name</FIRSTNAME>
<MIDNAME>Jr.</MIDNAME>
<LASTNAME>Last Name</LASTNAME>

请注意：

str-split-to-words 模板接受多个分隔符。因此，在此转换中使用的分隔符为：','、'(' 和 ')'

Answer 2

您需要一个递归命名模板。幸运的是，它已经被编写：在 http://www.exslt.org< 查找 str:tokenize /a>.

Answer 3

使用 substring-after() 和 substring-before() 来绕过分割