在 perl 中保存音译表

Question

我想用 0 音译 1 - 8 的数字，但在编译时不知道数字。由于音译不会插​​入变量，所以我这样做：

@trs = (sub{die},sub{${$_[0]} =~ tr/[0,1]/[1,0]/},sub{${$_[0]} =~ tr/[0,2]/[2,0]/},sub{${$_[0]} =~ tr/[0,3]/[3,0]/},sub{${$_[0]} =~ tr/[0,4]/[4,0]/},sub{${$_[0]} =~ tr/[0,5]/[5,0]/},sub{${$_[0]} =~ tr/[0,6]/[6,0]/},sub{${$_[0]} =~ tr/[0,7]/[7,0]/},sub{${$_[0]} =~ tr/[0,8]/[8,0]/});

然后将其索引为：

$trs[$character_to_transliterate](\$var_to_change);

如果有人能给我指出一个最好看的解决方案，我将不胜感激。

Answer 1

每当你重复自己时，你应该看看你正在做的事情是否可以循环完成。由于 tr 在编译时创建其表，因此您可以使用 eval 在运行时访问编译器：

my @trs = (sub {die}, map {eval "sub {\$_[0] =~ tr/${_}0/0$_/}"} 1 .. 8);

my $x = 123;

$trs[2]($x);

print "$x\n"; # 103

这里也不需要使用引用，子例程参数已经通过参考。

如果您不想使用字符串 eval，则需要使用支持运行时修改的构造。为此，您可以使用 s/// 运算符：

sub subst {$_[0] =~ s/($_[1]|0)/$1 ? 0 : $_[1]/ge}

my $z = 1230;

subst $z => 2;

print "$z\n"; # 1032

tr/// 构造比 s/// 更快，因为后者支持正则表达式。

Answer 2

我建议简单地放弃 tr，转而使用实际上允许一点元编程的东西，例如 s///。例如：

# Replace $to_swap with 0 and 0 with $to_swap, and leave
# everything else alone.
sub swap_with_0 {
    my ($digit, $to_swap) = @_;
    if ($digit == $to_swap) {
        return 0;
    } elsif ($digit == 0) {
        return $to_swap;
    } else {
        return $digit;
    }
}

# Swap 0 and $to_swap throughout $string
sub swap_digits {
    my ($string, $to_swap) = @_;
    $string =~ s/([0$to_swap])/swap_with_0($1, $to_swap)/eg;
    return $string;
}

这非常简单。 :)

Answer 3

这是一个使用替换而不是音译的简短子例程：

sub swap_digits {
    my ($str, $digit) = @_;
    $str =~ s{ (0) | $digit }{ defined $1 ? $digit : 0 }gex;
    return $str;
}