帮助在 Perl 中传递对类子例程的引用

Question

我正在尝试将一个例程传递给 Perl 模块中的另一个子例程。但是当我传递子引用时，传入的 ref 不再具有对象数据。也许这样是不可能做到的。我有疑问的那一行是下面的“除非”行：

sub get_flag_end {
   my $self = shift;
   return ( -e "$self->{file}" );
}

sub wait_for_end {
   my $self = shift;
   my $timeout = shift;
   my $poll_interval = shift;

   # Is it even possible to pass the oject subroutine and retain the objects data?
   #unless ( $self->timeout( $timeout, $poll_interval, $self->get_flag_end ) ) { # does not work
   unless ( $self->timeout( $timeout, $poll_interval, \&get_flag_end ) ) {       # call happens but members are empty
      die "!!!ERROR!!! Timed out while waiting for wait_for_end: timeout=$timeout, poll_interval=$poll_interval \n";
   }
}

sub timeout {
   my $self = shift;
   my $timeout = shift;
   my $poll_interval = shift;
   my $test_condition = shift;
   until ($test_condition->() || $timeout <= 0) {
      $timeout -= $poll_interval;
      sleep $poll_interval;
   }
   return $timeout > 0; # condition was met before timeout
}

我知道我可以更改“get_flag_end”例程以将该值作为子例程的参数，但是如果“get_flag_end”中完成了一堆事情怎么办我需要该对象的更多成员。我稍微简化了代码，使其更容易理解。

Answer 1

只需创建一个闭包并将其传入：

sub wait_for_end {
   my $self = shift;
   my $timeout = shift;
   my $poll_interval = shift;

   my $callback = sub { $self->get_flag_end() };

   unless ( $self->timeout( $timeout, $poll_interval, $callback ) ) {
      die "!!!ERROR!!! Timed out while waiting for wait_for_end: timeout=$timeout, poll_interval=$poll_interval \n";
   }
}

Update:

另一个选项是，由于 timeout 是同一类的方法，因此传入方法名称。

sub wait_for_end {
   my $self = shift;
   my $timeout = shift;
   my $poll_interval = shift;

   my $callback = sub { $self->get_flag_end() };

   unless ( $self->timeout( $timeout, $poll_interval, 'get_flag_end' ) ) {
      die "!!!ERROR!!! Timed out while waiting for wait_for_end: timeout=$timeout, poll_interval=$poll_interval \n";
   }
}

sub timeout {
  my $self = shift;
  my $timeout = shift;
  my $poll_interval = shift;
  my $method = shift;

  # Do whatever

  # Now call your method.
  $self->$method();

}

Answer 2

在您的 $test_condition->() 行中，您正在调用子例程，但不向其传递任何参数。您的意思很可能是 $test_condition->($self) 或者可能是 $self->$test_condition

这是您的代码的重构，纠正了一些其他问题：

sub get_flag_end {
   my $self = shift;
   return -e $self->{file}; # no need to quote the variable
}

sub wait_for_end {
   my ($self, $timeout, $poll_interval) = @_;  # unpack many args at once

   unless ( $self->timeout( $timeout, $poll_interval, $self->can('get_flag_end') ) ) {
      die "!!!ERROR!!! Timed out while waiting for wait_for_end: timeout=$timeout, poll_interval=$poll_interval \n";
   }
}

sub timeout {
   my ($self, $timeout, $poll_interval, $test_condition) = @_;
   until ($self->$test_condition || $timeout <= 0) {
      $timeout -= $poll_interval;
      sleep $poll_interval;
   }
   return $timeout > 0; # condition was met before timeout
}

根据您的实现的其余部分，创建一个知道其调用者的子例程可能会更好。您可以在 Perl 中使用闭包执行此操作：

unless ( $self->timeout( $timeout, $poll_interval, sub {$self->get_flag_end} )){

这里创建了一个新的子例程，它会记住 $self 的值。您可以不带参数调用它 $test_condition->()