在 Mathematica 中以明确可见的形式显示

Question

继续我的矩阵乘法问题 ，我想在 mma 中以显式可视形式显示以下表达式：

即使在在我给出 a11, ..., b11, ... 显式数字的情况下，我仍然希望它是未评估形式的 (0&&1)||(1&1) 。有人可以帮忙吗？

Answer 1

(0&&1)||(1&&1) 不评估，所以我没有看到问题。对于 True 和 False 您是否尝试过使用 HoldForm？

Answer 2

实现此目的的一种方法是定义您自己的矩阵包装器。包装器方法的优点是您可以重载任意数量的内置函数，而不会影响任何其他功能。

让我们首先定义一个名为 myMatrix 的包装器，它使用 MatrixForm 显示自身：

Format[myMatrix[m_]] ^:= MatrixForm[m]

接下来，我们将在 Times 运算符作用于 时重载它。 >myMatrix：

myMatrix[m1_] myMatrix[m2_] ^:= myMatrix[Inner[And, m1, m2, Or]]

请注意，这两个定义都使用 ^:= 将规则作为上值附加到 myMatrix。这对于确保常规内置定义不受影响至关重要。

有了这些定义，我们现在就可以实现预期的目标了。为了进行演示，我们定义两个矩阵：

m1 = myMatrix[Array[Subscript[a, Row[{##}]]&, {2, 2}]]

m2 = myMatrix[Array[Subscript[b, Row[{##}]]&, {2, 2}]]

现在可以生成所请求的“显式可见表单”：

Row[{m1, m2}] == m1 m2

。 .. 或者，如果您希望在等式左侧显式引用 Times：

With[{m1 = m1, m2 = m2}, HoldForm[m1 m2] == m1 m2]

接下来，我们将为每个矩阵元素分配随机布尔值：

Evaluate[First /@ {m1, m2}] = RandomInteger[1, {2, 2, 2}];

...然后使用适当的分配再次生成显式可见的形式：

With[{m1 = m1, m2 = m2}, HoldForm[m1 m2] == m1 m2]

Answer 3

使用

Inner[And, Array[Subscript[a, ##] &, {2, 2}], 
  Array[Subscript[b, ##] &, {2, 2}], Or] // MatrixForm

编辑。跟进您之前的问题后，我认为您可能会考虑

Inner[HoldForm[And[##]] &, amat, 
  bmat, HoldForm[Or[##]] &] // MatrixForm

Answer 4

我不认为这是一个真正的好主意（重载内部函数和所有；并且 && 不是 BitAnd，您想在上一个问题中使用它），但是您要求它并得到它：

CircleTimes[a_?MatrixQ, b_?MatrixQ] := 
 Inner[HoldForm[BitAnd[##]] &, a, b, HoldForm[BitOr[##]] &]

Unprotect[BitAnd];
Unprotect[BitOr];
BitAnd /: Format[BitAnd[a_, b_]] := a && b;
BitOr /: Format[BitOr[a_, b_]] := a || b;
Protect[BitAnd];
Protect[BitOr]

mat1 = Array[Subscript[a, #1, #2] &, {2, 2}];
mat2 = Array[Subscript[b, #1, #2] &, {2, 2}];

< img src="https://i.sstatic.net/sK9tA.png" alt="新定义的 CircleTimes 的输出">

将操作定义为 CircleTimes 的优点是您可以免费获得 CircleTimes 符号和运算符。