在perl中重写一个递归函数，以便它可以在列表上下文中使用

Question

考虑 Moose::Cookbook 中开发的二叉树::Basics::Recipe3

要检索所有节点按顺序，我可以添加下面的子例程到 BinaryTree 包

sub pre_order {
  my ($self,$aref) = @_;

  push @$aref, $self->node;

  pre_order($self->left,$aref) if $self->has_left;
  pre_order($self->right,$aref) if $self->has_right;
}

子例程必须像这样使用：

my $btree = BinaryTree->new;
#add some nodes

#then later...
my @nodes_in_preorder;
$btree->pre_order(\@nodes_in_preorder);

我必须如何更改子例程才能使用如下语法：

my @nodes_in_preorder = $btree->pre_order();

以便能够执行

for ($btree->pre_order()) { #bla bla } 

稍后的操作。

这有道理吗，还是我太迂腐了？

Answer 1

怎么样：

sub pre_order {
  my $self = shift;
  return ($self->node,
    $self->has_left ? $self->left->pre_order : (),
    $self->has_right ? $self->right->pre_order : ());
}

Answer 2

您可以只更改调用者：

for ( do { my @preorder; $btree->pre_order(\@preorder); @preorder } ) {

或者简单地更改代码，如下所示：

sub pre_order {
    my ($self,$aref) = @_;

    push @$aref, $self->node;

    $self->left->pre_order($aref) if $self->has_left;
    $self->right->pre_order($aref) if $self->has_right;

    return @$aref if wantarray;
}

无需将数组引用传递给外部调用；将自动创建一个，因此您的代码将正常工作（TM）：

for ( $self->pre_order() ) {