Vim 脚本：缓冲区/CheatSheet 切换

Question

我想做一个 vim 备忘单插件。这真的很简单：

• 我想切换我的备忘单。 vertsplit 切换，如 Taglist 或 NERDTree。
• 我希望备忘单是特定于文件类型的。因此，当我打开 .cpp 文件时，我会切换我的 C++ 备忘单。
• 我希望备忘单水平分割。所以它显示了两个文件，我的语法备忘单和我的片段触发器备忘单。

我已经收集了这些备忘单，采用 vimhelp 格式，但现在我必须手动打开它们。

我还没有真正编写过任何 vim 脚本，但我想这会很容易组合在一起。我有点厌倦了在谷歌上搜索不相关的代码片段，所以我在这里问的是：

1. 有人能给我一个关于 vim 脚本我需要学习的简短总结吗？我很难找到如何切换缓冲区窗口。

2. 如果您知道任何介绍性教程涵盖了我启动并运行此程序所需的材料，请提供一个链接。

TX,

活动b

Answer 1

下面的函数可能无法完全满足您的要求，而且我还没有测试过它，但它应该可以给您一些想法。

主要思想是该函数读取当前缓冲区的文件类型（您可以通过键入 :echo &ft 进行测试），然后设置适当的备忘的路径。如果存在，则在拆分窗口中打开该路径（只读且不可修改）。然后，您可以按照您希望的方式调用此函数，例如将其映射到 {F5} 键，如图所示。

我不确定切换的可能性（这真的比关闭分割窗口更容易吗？），但您可以查看 bufloaded() 函数，该函数返回当前是否正在访问给定文件。

function! Load_Cheat_Sheet()
    let l:ft = &ft

    if l:ft == 'html'
        let l:path = 'path/to/html/cheat/sheet'
    elseif l:ft == 'c'
        let l:path = 'path/to/c/cheat/sheet'
    elseif l:ft == 'tex'
        let l:path = 'path/to/tex/cheat/sheet'
    endif

    if l:path != '' && filereadable(l:path)
        execute ':split +setlocal\ noma\ ro ' l:path
    endif
endfunction

map <F5> :call Load_Cheat_Sheet()<CR>

希望这有帮助。如果有任何不清楚的地方，或者您想了解更多，请大声喊出来。

Answer 2

我已经忘记了这一点，直到我收到 Eduan 的回答。自从我发布这个问题以来，我已经编写了相当多的 vim 脚本，包括让它工作：

let g:cheatsheet_dir = "~/.vim/bundle/cheatsheet/doc/"                                                                     
let g:cheatsheet_ext = ".cs.txt"

command! -nargs=? -complete=customlist,CheatSheetComplete CS call ToggleCheatSheet(<f-args>)           
nmap <F5> :CS<CR>

" strip extension from complete list    
function! CheatSheetComplete(A,L,P)
  return map(split(globpath(g:cheatsheet_dir, a:A.'*'.g:cheatsheet_ext)),                           
       \ "v:val[".strlen(expand(g:cheatsheet_dir)).                                                     
       \ ":-".(strlen(g:cheatsheet_ext) + 1)."]")                                                              
endfun

" specify cheatsheet or use filetype of open buffer as default
" instead of saving window status in a boolean variable, 
" test if the file is open (by name). If a boolean is used, 
" you'll run into trouble if you close the window manually with :wq etc                           
function! ToggleCheatSheet(...)
  if a:0    
    let s:file = g:cheatsheet_dir.a:1.g:cheatsheet_ext
  else                                     
    if !exists("s:file") || bufwinnr(s:file) == -1                                                                                 
      let s:file = g:cheatsheet_dir.&ft.g:cheatsheet_ext
    endif
  endif                                    
  if bufwinnr(s:file) != -1
    call ToggleWindowClose(s:file)
  else
    call ToggleWindowOpen(s:file)
  endif                 
endfun             


" stateless open and close so it can be used with other plugins              
function! ToggleWindowOpen(file)           
  let splitr = &splitright
  set splitright                           
  exe ":vsp ".a:file  
  exe ":vertical resize 84"
  if !splitr    
    set splitright
  endif                        
endfun

function! ToggleWindowClose(file)    
  let w_orig = bufwinnr('%')
  let w = bufwinnr(a:file)
  exe w.'wincmd w'
  exe ':silent wq!'      
  if w != w_orig        
    exe w_orig.'wincmd w'
  endif
endfun                                            

Answer 3

我想我应该补充一下炖牛肉的答案。

我认为为了实现切换，您只需使用一些 if 语句和全局变量即可。

let g:cheatsheet_toggle_on=0

if (g:cheatsheet_toggle_on == 0)
    " Turn the cheatsheet on
    " Also make sure to know that the toggle is on:
    let g:cheatsheet_toggle_on=1
elseif (g:cheatsheet_toggle_on=1
    " Do whatever you need to turn it off, here
endif

希望这能弄清楚这个逻辑。 :)