方案函数中的右括号放置不当

Question

我有以下方案函数：

(define get-ivars
  (λ (ivars num)
    (cond ((null? ivars) '())
          (else
           (append (list (car ivars) `(nth args ,num)) (list (get-ivars (cdr ivars) (+ num 1))))))))

在特定实例中返回以下内容：

(x (nth args 1) (y (nth args 2) ()))

问题是，我需要它返回：

((x (nth args1)) (y (nth args 2)) ())

- 末尾的两个右括号应该在 (nth 语句之后。

我如何将其变为 工作正常吗？

get-ivars 调用者

(define gen-classes
  (λ (classes)
    (cond ((null? classes) '())
          (else
           (let* ((class (car classes)))
             (eval
              `(define ,(cadr class)
                 (λ (args)
                   (let (
                          ,(get-ivars (cdr (cadddr class)) 1)
                          )
                     (eval
                      (let* ,(cdar (cddddr class))
                        (λ (method . args)
                          ,(get-methods (cdadr (cddddr class)))
     ))))))))))))

Answer 1

else 子句中的第二个 (list ...) 才是让你陷入困境的原因。它使每个连续的调用嵌套得越来越深。递归自然会创建列表；你不需要再把它包裹起来。

尝试：

(define get-ivars
  (λ (ivars num)
    (if (null? ivars) '()
      (cons (list (car ivars) `(nth args ,num)) 
            (get-ivars (cdr ivars) (+ num 1))))))

关于 get-ivars 调用者代码，对 get-ivars 的未引用调用周围的括号是给您在评论中提到的麻烦的原因。有了它们，这段代码：

`(define ClassName
   (lambda (args)
     (let (,(get-ivars '(iVar1 iVar2 iVar3) 1))
       ;; your method-getting code
       )))

给你这个：

(define ClassName
  (lambda (args)
    (let (((iVar1 (nth args 1))
           (iVar2 (nth args 2))
           (iVar3 (nth args 3))))
      ;; method-getting code
     )))

正如你所看到的，它为你在 let 中的赋值周围提供了一组额外的括号。

所以你想这样做：

`(define ClassName
   (lambda (args)
     (let ,(get-ivars '(iVar1 iVar2 iVar3) 1)
        ;; your method-getting code
      )))

get-ivars返回一个列表列表，这正是你想要的let中的分配，所以你不需要包裹或（就像我之前那样）拼接它。只需单独使用取消引号，结果是：

(define ClassName
  (lambda (args)
    (let ((iVar1 (nth args 1))
          (iVar2 (nth args 2))
          (iVar3 (nth args 3)))
      ;; method-getting code
     )))

哪个应该可以解决问题。

顺便说一句，我发现当我在玩这个时，放弃eval很有帮助；然后可以目视检查结果以确保其语法正确。

Answer 2

我没有尝试过，但我认为这会起作用：

(define (get-ivars ivars num)
    (if (null? ivars)
    '()
    (list (list (car ivars) `(nth args ,num))
          (get-ivars (cdr ivars) (1+ num)))))