批处理文件加密多个档案

Question

我有一组 ZIP 存档，位于Folder1\ 内的一组文件夹中，每个文件夹有多个 zip 文件。

我想在另一个目标文件夹 Destination\ 中创建此文件夹结构的副本，但所有 ZIP 文件均已加密。

Folder1\ 内的文件夹的嵌套永远不会超过一个，但递归到文件夹中的通用解决方案会很好。

我已经搞乱了子字符串，但无法让它工作。我确信我只有 % 的距离，但它让我难住了：

for /D %%S in (.\*) do (
  echo %%S
  set PN=%%S:~2,99%
  echo %PN%
  for %%F in (%%S\*.zip) do (

    echo "%UserProfile%\Desktop\Destination\%PN%\%%~nxF"
    )
  )

%%S 返回“.\Folder”形式的路径，而“set PN=%%S:~2,99%”应该是删除“.\”，但它没有发生。

echo $$S 显示“.\Folder”（不带引号），这是可以的
echo %PN% 显示“.\Folder:~2,99”，这是不行的，

我对解压缩/压缩没问题，只是路径名让我难住了。

Answer 1

您的脚本存在一些问题。

1. 不能将子字符串表达式与循环变量一起使用。您必须将其值存储到环境变量（例如 SET name=%%S）并从该变量中提取子字符串。

2. 如果不启用变量的延迟扩展，如果变量是在同一个块中初始化的，则您将无法在括号内的命令块内使用环境变量。问题是，在解析父命令的同时解析块内的命令（并评估变量）（在本例中为 FOR）。因此，很可能您总是会用一个空字符串来代替 %PN%。

3. 实际上您不需要 PN 变量。似乎您引入它只是为了删除文件夹名称的 .\ 部分。但您不必在外部 FOR 循环中使用 .\* 掩码，只需使用 * 即可。 （不过，如果 .\* 对您来说更有意义，您可以简单地使用 %%~nxS 来替换文件夹的名称。）

因此，这应该给出您的预期输出：

for /D %%S in (*) do (
  for %%F in ("%%S\*.zip") do (
    echo "%UserProfile%\Desktop\Destination\%%S\%%~nxF"
    )
  )

如果您坚持使用 .\* 掩码：

for /D %%S in (.\*) do (
  for %%F in ("%%~nxS\*.zip") do (
    echo "%UserProfile%\Desktop\Destination\%%~nxS\%%~nxF"
    )
  )