Perl Moose - 检查变量是否是 Moose 数据类型

Question

我正在将遗留应用程序转换为使用 Moose（和 Catalyst）并有以下问题。

如何确定用户输入的数据的 Moose 类型？

在下面的粗略示例中，我“提交”多个查询，并使用下面非常基本的“验证”方法根据预期的表单字段“id”、“name”和“email”验证数据。

use MooseX::Declare;
class CheckFields
{
    #has '_field' => ( is => 'rw', isa => 'Any' );

    # Fields on form and type to which they must match.
    method fields()
    {
        return [ { name => 'id',    type => 'Int' },
                 { name => 'name',  type => 'Str' },
                 { name => 'email', type => 'Email' }
               ];
    }

    # Dummy form posted requests.
    method queries()
    {
        return [ { 'id'    => 1,
                   'name'  => 'John Doe',
                   'email' => '[email protected]'
                 },
                 { 'id'    => 'John Doe',
                   'name'  => 1,
                   'email' => 'john.at.doe.net'
                 }
               ];
    }

    method validate_fields()
    {
        my $fields = $self->fields();

        # Loop through dummy form post requests
        foreach my $query ( @{ $self->queries } )
        {
            # Validate each field in posted form.
            foreach my $field ( @{ $fields } )
            {
                my $type = $field->{'type'};
                my $name = $field->{'name'};

                my $res = $self->validate->{ $type }( $query->{ $name} );
                print "$name is $res\n";
            }
            print "\n";
        }
    }

    # Very basic, slightly crude field validation.
    method validate()
    {
        return { 'Int'   => sub { my $val = shift; return $val =~ /^\d+$/ ? "ok" : "not ok" },
                 'Str'   => sub { my $val = shift; return $val =~ /^[a-zA-Z\s]+$/ ?"ok" : "not ok"  },
                 'Email' => sub { my $val = shift; return $val =~ /^(.+)\@(.+)$/ ?"ok" : "not ok"  }
               };
    }
}

要测试此代码，只需运行...

#!/usr/bin/perl
use Moose;
use CheckFields;

CheckFields->new()->validate_fields();

1;

是否可以执行类似的操作，将 isa 设置为“Any”...

has '_validate_field' => ( is => 'rw', isa => 'Any' );

然后测试特定类型，如下所示？

$self->validate_field(1);
print $self->validate_field->meta->isa('Int') ? 'Int found' : 'Int not found';

$self->validate_field('ABC');
print $self->validate_field->meta->isa('Int') ? 'Int found' : 'Int not found';

提前感谢您

编辑：@bvr - 感谢您花时间回复，我对 Moose 比较陌生，所以您使用 MooseX::Params::Validate 很可能是最终的解决方案不完全是我想要的。我的目的是能够报告错误的每个特定字段，而不是报告整个验证失败。为此，我想我可以定义一个默认的、对 Moose 友好的输入持有者，并将 isa 设置为“Any”。然后“eval”（或类似的）来查看数据是否符合特定类型（Int、Str 或我定义的某些自定义类型）。

我试图通过“$self->validate_field->meta->isa('Int')...”引用来达到 C/C++ 中联合的目的，其中变量可以可以是不同的类型 - 在这种情况下，我只是想测试数据是否符合某种数据类型。

Answer 1

我不确定我是否完全遵循您问题的最后部分，但您最初的示例可以受益于使用 MooseX::Params::Validate。

编辑：我编写了一些代码来评估我的建议。

use MooseX::Declare;
class CheckFields {

    use Moose::Util::TypeConstraints;
    use MooseX::Params::Validate;
    use Try::Tiny;
    use Data::Dump qw(pp);

    subtype 'Email' 
        => as 'Str' 
        => where {/^(.+)\@(.+)$/};

    method fields() {
        return [
            id    => {isa => 'Int'},
            name  => {isa => 'Str'},
            email => {isa => 'Email'},
        ];
    }

    method queries() {
        return [
            {   'id'    => 1,
                'name'  => 'John Doe',
                'email' => '[email protected]'
            },
            {   'id'    => 'John Doe',
                'name'  => 1,
                'email' => 'john.at.doe.net'
            }
        ];
    }

    method validate_fields() {
        my $fields = $self->fields();

        foreach my $query (@{$self->queries}) {
            try {
                my (%params) = validated_hash([%$query], @{$fields});
                warn pp($query) . " - OK\n";
            }
            catch {
                warn pp($query) . " - Failed\n";
            }
        }
    }
}

package main;

CheckFields->new()->validate_fields();

我能看到的其他方法是为数据创建一个 Moose 类（包括这种方式的验证）并检查是否可以在没有验证错误的情况下创建实例。像这样的事情：

use MooseX::Declare;
class Person {
    use Moose::Util::TypeConstraints;

    subtype 'Email'
        => as 'Str'
        => where {/^(.+)\@(.+)$/};

    has id    => (is => 'ro', isa => 'Int');
    has name  => (is => 'ro', isa => 'Str');
    has email => (is => 'ro', isa => 'Email');
}

package main;

use Try::Tiny;
use Data::Dump qw(pp);

my @tests = (
    { id => 1,          name => 'John Doe', email => '[email protected]'},
    { id => 'John Doe', name => 1,          email => 'john.at.doe.net'},
);

for my $query (@tests) {
    try {
        my $person = Person->new(%$query);
        warn pp($query) . " - OK\n";
    }
    catch {
        warn pp($query) . " - Failed\n";
    };
}