我怎样才能使这更地道？

Question

这是我从另一种语言（Lisp）翻译而来的函数，大部分是逐字翻译的。不过，我觉得不太对劲，如果使用 ref、if 而不使用 else 等等，你会如何重写第二个函数以下？

let directEdges node edges =
    List.filter (fun (a, b) -> a = node) edges

let getConnected node edges =
    let visited = ref Set.empty
    let rec traverse node =
        if not (Set.contains node !visited) then
            visited := Set.add node !visited
            directEdges node edges 
            |> List.iter (fun (a, b) -> traverse b)
    traverse node        
    !visited

编辑：也没有要求代码甚至使用 Set；原来只是使用了一个列表。

Answer 1

总的来说，我认为你的解决方案看起来相当不错 - 我认为这是一种稍微可变性使算法的表达更清晰的问题。但是，与其使用对重复更新的不可变集的可变引用，不如仅使用可变集实现：

open System.Collections.Generic

let getConnected node edges =
  let visited = HashSet()
  let rec traverse node = 
    if not (visited.Contains node) then
      visited.Add node
      directEdges node edges
      |> List.iter (fun (a,b) -> traverse b)
  traverse node
  visited

如果您希望输出是不可变集，则只需添加 |> ;设置在最后一行之后。

另一方面，如果您想使用函数式方法，这并不太难：

let getConnected node edges =  
  let rec traverse node visited =       
    if not (Set.contains node visited) then
      directEdges node edges             
      |> List.fold (fun nodes (a, b) -> traverse b nodes) (Set.add node visited)
    else
      visited
  traverse node Set.empty