我怎样才能做出“工作”？有理数的重复十进制表示？

Question

我已经弄清楚如何使用 OverBar 显示重复小数的重复部分。

repeatingDecimal 实际上并不用作重复小数。我想对其进行变体，使其看起来和都像重复的小数。

---

问题

如何制作工作重复十进制表示（可能使用Interpretation[]）？

---

背景

如果我胡言乱语，请原谅。这是我的第一个问题，我想弄清楚我的想法。

下面将“绘制”一个循环小数。

repeatingDecimal[q2_] :=
 Module[{a},
  a[{{nr__Integer}, pt_}] := 
   StringJoin[
    Map[ToString, 
     If[pt > -1, Insert[{nr}, ".", pt + 1], 
      Join[{"."}, Table["0", {Abs[pt]}], {nr}]]]];
  (* repeating only *)

  a[{{{r__Integer}}, pt_}] := 
   Row[{".", OverBar@StringJoin[Map[ToString, {r}]]}];

  (* One or more non-repeating; 
  more than one repeating digit KEEP IN THIS ORDER!! *)
  a[{{nr__, {r__}}, pt_}] := 
   Row[{StringJoin[
      Map[ToString, 
       If[pt > -1, Insert[{nr}, ".", pt + 1], 
        Join[{"."}, Table["0", {Abs[pt]}], {nr}]]]], 
     OverBar@StringJoin[Map[ToString, {r}]]}];
  (* One or more non-repeating; one repeating digit *)

  a[{{nr__, r_Integer}, pt_}] := 
   Row[{StringJoin[Map[ToString, {nr}]], ".", 
     OverBar@StringJoin[Map[ToString, r]]}];
  a[RealDigits[q2]]]

因此

repeatingDecimal[7/31]

正确显示重复小数（此处显示为图片，以便出现 OverBar）。

仔细一看，它实际上只是一个冒名顶替者，一个重复小数的图像......

In[]:= repeatingDecimal[7/31]//FullForm
Out[]:= Row[List[".",OverBar["225806451612903"]]]

当然，它的行为不像数字：

% + 24/31

我想要添加到产量：1

---

编辑：A RepeatingDecimal Leonid 的清理版本

展示了如何将 Format 包装在例程中，并为重复小数的加法和乘法提供向上值。非常有帮助！我需要一些时间才能适应数值的上下波动。

下面的内容本质上是 Mr.Wizard 建议的代码的简化版本。我将 OverBar 设置在每个重复数字上方以允许换行。 （行上方的单个 OverBar 看起来更整洁，但在达到右侧屏幕边距时无法中断。）

ClearAll[repeatingDecimal]

repeatingDecimal[n_Integer | n_Real] := n

Format[repeatingDecimal[q_Rational]] := Row @ Flatten[
   {IntegerPart@q, ".", RealDigits@FractionalPart@q} /.
    {{nr___Integer, r_List: {}}, pt_} :> {Table[0, {-pt}], nr, OverBar /@ r}
  ]

repeatingDecimal[q_] + x_ ^:= q + x
repeatingDecimal[q_] * x_ ^:= q * x
repeatingDecimal[q_] ^ x_ ^:= q ^ x

下表显示了 repeatingDecimal 的一些输出：

n1 = 1; n2 = 15; ClearAll[i, k, r];
TableForm[Table[repeatingDecimal[i/j], {i, n1, n2}, {j, n1, n2}], 
TableHeadings -> {None, Table[("r")/k, {k, n1, n2}]}]

---

检查解决方案：使用重复小数进行运算

现在让我们检查重复小数的加法和乘法：

a = repeatingDecimal[7/31];
b = repeatingDecimal[24/31];
Print["a = ", a]
Print["b = ", b]
Print["a + b = ", a, " + ", b, " = ", a + b]
Print["7/31 \[Times] 24/31 = " , (7/31)* (24/31)]
Print["a\[Times]b = ", a*b, " = \n", repeatingDecimal[a*b]]
Print[N[168/961, 465]]

因此，重复小数的加法和乘法可以按需要进行。 Power 似乎也可以正常工作。

请注意，168/961 占据小数点右侧 465 位。之后，它开始重复。结果与 N[168/961, 465] 的结果匹配，除了 OverBar 之外，尽管换行发生在不同的位置。而且，正如所预料的，这与以下内容相符：

digits = RealDigits[168/961]
Length[digits[[1, 1]]]

---

Format[] 包装器对N[] 对重复小数求和的行为

Mr.Wizard 建议 Format 包装器对于整数和实数的情况是多余的。

让我们考虑一下以下两个加法

repeatingDecimal[7/31] + repeatingDecimal[24/31]
N@repeatingDecimal[7/31] + N@repeatingDecimal[24/31]

在四种不同情况下的表现：

情况 1：当 Format 包裹 围绕实数和整数及向上值的重复小数时的结果是 ON

正如预期的那样，第一个加法产生一个整数，第二个加法产生一个小数。

---

Case 2: Results when Format NOT wrapped around repeatingDecimals for Reals and Integers but up values are ON

Reals 和 Integers 的 Format 包装器不会影响手头的添加。

---

Case 3: Results when Format wrapped around repeatingDecimals for Reals and Integers but up values are OFF

如果 upvalues 为 OFF，Format 将阻止添加发生。

---

Case 4: Results when Format NOT wrapped around repeatingDecimals for Reals and Integers and up values are OFF

如果 upvalues 为 OFF 并且 Format` 对于实数和整数不包裹重复小数，则第二次添加按预期工作。

更有理由删除实数和整数的格式包装器。

---

大家对案例3和案例4的不同结果有什么看法吗？

Answer 1

您不应该指定 repeatingDecimal DownVaues，而应该指定 FormatValues：

ClearAll[repeatingDecimal];
Format[repeatingDecimal[q2_]] := 
Module[{a}, 
 a[{{nr__Integer}, pt_}] := 
 StringJoin[
  Map[ToString, 
   If[pt > -1, Insert[{nr}, ".", pt + 1], 
  Join[{"."}, Table["0", {Abs[pt]}], {nr}]]]];
  (*repeating only*)
 a[{{{r__Integer}}, pt_}] := 
 Row[{".", OverBar@StringJoin[Map[ToString, {r}]]}];
(*One or more non-repeating;
more than one repeating digit KEEP IN THIS ORDER!!*)
a[{{nr__, {r__}}, pt_}] := 
 Row[{StringJoin[
   Map[ToString, 
    If[pt > -1, Insert[{nr}, ".", pt + 1], 
     Join[{"."}, Table["0", {Abs[pt]}], {nr}]]]], 
  OverBar@StringJoin[Map[ToString, {r}]]}];
(*One or more non-repeating;one repeating digit*)
a[{{nr__, r_Integer}, pt_}] := 
  Row[{StringJoin[Map[ToString, {nr}]], ".", 
   OverBar@StringJoin[Map[ToString, r]]}];
a[RealDigits[q2]]]

然后，您也可以指定 UpValues >，与常见函数集成，例如：

repeatingDecimal /: Plus[left___, repeatingDecimal[q_], right___] := left + q + right;
repeatingDecimal /: Times[left___, repeatingDecimal[q_], right___] :=  left * q * right;

然后，例如，

In[146]:= repeatingDecimal[7/31]+24/31

Out[146]= 1

您可以将此方法扩展到您可能想要使用 repeatingDecimal 的其他常见函数。

Answer 2

这是更新后的代码的可能重构。我认为这次有效（手指交叉）。如果不需要颜色突出显示，则可以省略 ~Style~ 和该行的其余部分。

ClearAll[repeatingDecimal];

Format[repeatingDecimal[n_Integer | n_Real]] := n;

Format[repeatingDecimal[q_Rational]] :=
 Row[{IntegerPart@q, ".", RealDigits@FractionalPart@q}] /.
  {{ nr___Integer, r_List:{} }, pt_} :>
   Row@Join[
      "0" ~Table~ {-pt},
      {nr},
      If[r === {}, {}, {OverBar@Row@r}]
      ] ~Style~ If[r === {}, Blue, If[{nr} === {}, Red, Gray]]

repeatingDecimal /:
  (h : Plus | Times)[left___, repeatingDecimal[q_], right___] :=
    h[left, q, right];

我将把这个旧版本留在这里供参考，但我现在正在对问题社区 wiki 进行编辑。