如何使用 PERL、正则表达式仅将文件名（非完整路径）放入 $1

Question

我只想保留文件名（而不是完整路径）并将文件名添加到某些 bbcode 中。

这是要转换的 HTML：

<a href=/path/to/full/image.jpg rel=prettyPhoto><img rel=prettyPhoto src=/path/to/thumb/image.jpg /></a>

注意，我不能有 rel="foo" （没有双引号）..

这是我在 PERL 中执行转换的内容：

s/\<a href=(.+?)\ rel=prettyPhoto\>\<img rel=prettyPhoto src=(.+?) \/>\<\/a\>/\[box\]$1\[\/box\]/gi;

这会将 HTML 转换为：

[box]/path/to/image.jpg[/box]

但这就是我想要的结果：

[box]image.jpg[/box]

HTML 必须保持不变。那么如何更改 PERL 以使 $1 只包含文件名呢？

Answer 1

s/\<a href=(?:.*\/)?(.+?)\ rel=prettyPhoto\>\<img rel=prettyPhoto src=(.+?) \/>\<\/a\>/\[box\]$1\[\/box\]/gi;

(?:.*\/)?

将匹配以 / 结尾的最长部分。最后的 ? 使其成为可选的。

Answer 2

我不知道它是否可以处理边缘情况，但我让它工作：

#!/usr/bin/perl

use strict;
use warnings;

my $in = '<a href=/path/to/full/image.jpg rel=prettyPhoto><img rel=prettyPhoto src=/path/to/thumb/image.jpg /></a>';

$in =~ s/\<a href=.*?([^\/]+)\ rel=prettyPhoto\>\<img rel=prettyPhoto src=(.+?) \/>\<\/a\>/\[box\]$1\[\/box\]/gi;

print $in . "\n";

但是，您不想做类似的事情吗：

#!/usr/bin/perl

use strict;
use warnings;

use HTML::TokeParser;
my $p = HTML::TokeParser->new(\*DATA);

my $token = $p->get_tag("a");
my $token_attribs = $token->[1];
my $bb_code;

if ($token_attribs->{rel} eq 'prettyPhoto') {

  my $url = $token_attribs->{href};
  my @split_path = split(m'/', $url);

  $bb_code = '[box]' . $split_path[-1] . '[/box]';
}

print $bb_code . "\n";
__DATA__
<a href=/path/to/full/image.jpg rel=prettyPhoto><img rel=prettyPhoto src=/path/to/thumb/image.jpg /></a>

使用 HTML 解析器（如 HTML::TokeParser，文档中有示例）为您找到网址？比手动调整 HTML 好得多。

Answer 3

我建议您使用正确的工具来完成这项工作，例如：

use HTML::PullParser;
use URI;

die '' . $! || $@ 
    unless my $p = HTML::PullParser->new(
      doc         =>  $doc_handle
    , start       => 'tag, attr'
    , report_tags => ['a']
    );

my @file_names;
while ( my $t = $p->get_token ) { 
    next unless $t    and my ( $tag_name, $attr ) = @$t;
    next unless $attr and my $href = $attr->{href};
    next unless my $uri = URI->new( $attr->{href} );
    next unless my $path = $uri->path;
    push @file_names, substr( $path, rindex( $path, '/' ) + 1 );
    # or it's safe to use a regex here:
    # push @file_names, $path =~ m{([^/]+)$};
}

Data::Dumper->Dump( [ \@file_names ], [ '*file_names' ] );

朋友不允许朋友使用正则表达式解析 HTML。

Answer 4

不要捕捉整个事情。将非捕获组与 (?:...) 一起使用。这样你就可以进一步细分你匹配的部分和你捕获的部分。

Answer 5

这显然在正则表达式中不起作用，但您可以运行 split 对 $1 执行函数并获取结果数组的最后一个元素。

Answer 6

怎么样：

s/\<a href=.*\/(.+?)\ rel=prettyPhoto\>\<img rel=prettyPhoto src=(.+?) \/>\<\/a\>/\[box\]$1\[\/box\]/gsi;