如何在 Flex4 中重新渲染 DropDownList 的 itemRenderer？

Question

我创建了一个自定义 ComboCheck，它扩展了 Spark DropDownList，它是复选框的 DropDownList。在我的 itemRenderer 内部，我有以下代码：

[Bindable]override public function set data (value:Object):void {
    if (value!=null) {
        _data = value;
        item.label = value.label;
        item.group = value.group;
        item.toolTip = value.toolTip;
        item.selected = value.selected;
        item.enabled = value.enabled;
    ...

该代码允许我启用和禁用下拉列表中的各个项目，以便在渲染时，您将无法选择我已禁用的项目。我正在尝试创建这样的功能：用户单击给定类别中的特定项目，这会导致所有其他类别被禁用，直到您取消选择所有内容。

我的问题是，当 DropDownList 启动时，项目已被渲染，因此更改应禁用的每个项目的 enabled 属性不会更改已渲染的项目。如果您向下滚动并向后滚动以重新渲染数据，它就可以正常工作。

有没有办法让 itemRenderer 重新渲染屏幕上的数据，以便刷新并应用此更新？

下面是所选项目的示例代码，它会禁用所有其他项目，然后仅启用您选择的那个。我还有一个 itemDeselect 函数，可以减少 itemCount 并启用所有内容 <代码>

private function itemSelect(evt:Event):void{
            itemCount++;
            var myText:String = '';
            var items:Vector.<Object> = allItems.selectedItems;
            if(itemCount == 1){
                    for each(var obj:Object in allItems.dataProvider){
                        obj.enabled = false;
                    }
            }
            for (var i:String in items) {
                if(items[i].group == "HU"){
                    items[i].enabled = true;
                    huList[items[i].label] = items[i].selected;
                }else if(items[i].group == "ALL"){
                    items[i].enabled = true;
                    allCase = items[i].selected;
                }else{
                    items[i].enabled = true;
                    otherList[items[i].label] = items[i].selected;
                }

            }

            selectionChanged = true;
}

<代码> 这可以工作，但它不会重新渲染，因此除非您向下滚动并向后滚动，否则 obj.enabled=false 不会出现。

编辑：最终解决方案
使用 www.Flextras.com 建议的第三个选项，我使用了 itemUpdated 属性 dataProvider.itemUpdated(obj)，因此在

for each(var obj:Object in allItems.dataProvider){
    obj.enabled = false;
    allItems.dataProvider.itemUpdated(obj);
}

内部，这也不会导致下拉列表重置为滚动位置 0

Answer 1

有没有办法让
itemRenderer 重新渲染数据
显示应用此更新？

我有三种方式。

1）使列表的dataGroup而不是列表无效。

listInput.dataGroup.invalidateDisplayList();

2) 刷新 dataProvider

(listInput.dataProvider as ArrayCollection).refresh();

3) 当 dataProvider 项更改时，调用集合上的 itemUpdated() 属性。抱歉，没有这方面的代码示例。

在这种情况下，我经常忘记做的一件事是实现渲染器，以便它知道将自己切换回“非活动”状态。因此，在 itemRenderer 的 set data 方法中，请务必添加一个 else 条件，将所有这些值恢复为默认值。

Answer 2

我找到了“重新渲染”的方法，只需重写设置数据函数并更新 itemRenderer 中的所有属性：例如，

我有一个 DataGrid，其中有一列带有 itemRenderer，该列为我的 dataProvider 中的每个项目显示不同的背景颜色。

<mx:DataGrid>
  <mx:columns>
    <mx:DataGridColumn itemRenderer="myItemRenderer"/>
  </mx:columns>
</mx:DataGrid>

//myItemRenderer：

override public function set data( value:Object ) : void {
  super.data = value;
  if( value > 0) setStyle("backgroundColor",0xff99ff);
  else setStyle("backgroundColor",0xffffff);
}

仅此而已。

Answer 3

您还可以将 dataChange 事件的事件侦听器添加到项目渲染器本身。更改 data 属性后会触发此事件。

<s:ItemRenderer dataChange="updateView(event)">
    <fx:Script>
        <![CDATA[
            protected function updateView(event:Event):void{
                //update logic
            }
        ]]>
    </fx:Script>
</s:ItemRenderer>