Maple 代码生成：如何自动声明变量？

Question

在 Maple（版本 14，如果重要的话）中，我定义了一个在 Maple 中使用全局定义表达式的过程，但是当我进行代码生成时，它假设该变量不是我所期望的。

a:=x+y*x
p := proc (x::float, y::float); return a; end proc;
C(p)

我期望的是一个 C 函数，并将表达式插入到代码中，但我得到了......

double p (double x, double y)
{
  return(a);
}

Answer 1

这是“设计”的事情之一。尽管在这种特殊情况下你可能会觉得很尴尬，但（现代）Maple 的这种词汇范围行为通常是一个优势，而且是经过深思熟虑的。有多种方法可以满足您的期望。

在这种情况下，最简单的解决方法可能就是这样：

restart:
a:=x+y*x:
p := proc(x::float, y::float) return a; end proc;

          p := proc(x::float, y::float) return a end proc;

CodeGeneration:-C( subs('a'=a,eval(p)) );

  double cg (double x, double y)
  {
     return(x + y * x);
  }

上面完成的是 subs('a'=a,eval(p)) 形成 proc p 的一个新实例 其中 a 在 proc 主体中被 a 的显式值替换（即 a 的计算结果）。请注意以下输出，并与最初创建 p 时的上面输出进行比较，

subs('a'=a,eval(p));

   proc(x::float, y::float) return x + y*x end proc;

请记住，即使在这个非常简单的解决方法示例中并不明显，全局名称的给定替换将 x 和 y 放入 p 的副本中实际上是在利用 Maple 的作用域规则玩一个棘手的游戏。在更复杂的范围界定情况下，这可能会变得疯狂。但如果您真正想要的是内联，那么您可以通过更明确和受控的方式来实现。查看在下一个示例中最初创建时 p 的回显输出，

restart:
a := proc(A,B) option inline; A+B*A: end proc;
          a := proc(A, B) option inline; A + B*A end proc;

p := proc(x::float, y::float) return a(x,y); end proc;
       p := proc(x::float, y::float) return x + y*x end proc;

CodeGeneration:-C( p );

   double p (double x, double y)
   {
     return(x + y * x);
   }

希望这两种方法足以帮助您完成任务。

让我们简单地回到原来的例子，只是为了注意一些事情。 a 值中出现的全局名称 x 和 y 与两个形式参数的名称非常不同最初创建的过程p。它们是看似相同名称的完全不同的实例。考虑，

restart:
a:=x+y*x:

p := proc(x::float, y::float) return a; end proc;

          p := proc(x::float, y::float) return a end proc;

p(4.0, 5.0);
                               x + y x