交换字变量的字节（低/高）的过程

Question

我有一个交换 Word 变量的字节（低/高）的过程（它与 System.Swap 函数执行相同的操作）。该过程在编译器优化关闭时有效，但在编译器优化打开时无效。 有人能帮我解决这个问题吗？

procedure SwapWord(VAR TwoBytes: word);   
asm
  Mov EBX, TwoBytes
  Mov AX, [EBX]
  XCHG AL,AH
  Mov [EBX], AX
end;

Answer 1

最快：

function ReverseWord(w: word): word;
asm
   {$IFDEF CPUX64}
   mov rax, rcx
   {$ENDIF}
   xchg   al, ah
end;

如果您也想反转 DWORD：

function ReverseDWord(dw: cardinal): cardinal;
asm
  {$IFDEF CPUX64}
  mov rax, rcx
  {$ENDIF}
  bswap eax
end;

Answer 2

如果不保存/恢复，则无法在 ASM 代码中使用 EBX 寄存器。您的代码的更正版本是

procedure SwapWord_Working(VAR TwoBytes: word);   
asm
  PUSH EBX     // save EBX
  Mov EBX, TwoBytes
  Mov AX, [EBX]
  XCHG AL,AH
  Mov [EBX], AX
  POP EBX     // restore EBX
end;

Answer 3

让我有点惊讶的是，没有人提到“绝对”“黑客”，它已经存在了十多年，但没有引起太多关注……无论如何，这是我的两分钱

function SwapWordBytes(const Value: Word): Word;
var
  // shares memory with Value parameter
  LMemValue: array[0..1] of Byte absolute Value;
  // shares memory with Result
  LMemResult: array[0..1] of Byte absolute Result;
begin
  LMemResult[0] := LMemValue[1];
  LMemResult[1] := LMemValue[0];
end;

Answer 4

您是否考虑过使用编译器的 Swap 函数？

procedure TForm1.FormCreate(Sender: TObject);
var
  a: word;
begin
  a := $1234;
  a := Swap(a);
  Caption := IntToHex(a, 4)
end;

如果没有，则不需要 ASM（并且 ASM 可能在 64 位 Delphi 中不可用）。你可以这么做

procedure MySwap(var a: word);
var
  tmp: byte;
begin
  tmp := PByte(@a)^;
  PByte(@a)^ := PByte(NativeUInt(@a) + sizeof(byte))^;
  PByte(NativeUInt(@a) + sizeof(byte))^ := tmp;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  a: word;
begin
  a := $123456;
  MySwap(a);
  Caption := IntToHex(a, 4)
end;

，当然，这个主题有“一百万”个变体。

procedure MySwap(var a: word);
var
  tmp: byte;
type
  PWordRec = ^TWordRec;
  TWordRec = packed record
    byte1, byte2: byte;
  end;
begin
  with PWordRec(@a)^ do
  begin
    tmp := byte1;
    byte1 := byte2;
    byte2 := tmp;
  end;
end;

并且，非常简单地，

procedure MySwap(var a: word);
begin
  a := word(a shl 8) + byte(a shr 8);
end;

或者

procedure MySwap(var a: word);
begin
  a := lo(a) shl 8 + hi(a);
end;

Answer 5

尽管 Serg 的答案肯定是正确的，正如对 Serg 答案的评论中指出的那样，但它效率不高。最快的显然是 Gabr 的答案中提供的代码，但由于您明确需要一个过程，而不是一个函数，因此以下将是 Serg 例程的首选版本：

procedure SwapWord_Working2 (VAR TwoBytes: word);
asm
  mov dx, [TwoBytes]  ;//[TwoBytes] = [eax] on x86 *[Note1]
  xchg dl, dh
  mov [TwoBytes], dx
end;

[注 1：] Serg 的函数版本很可能会，不适用于即将推出的 x64 Delphi 编译器。假设 Embarcadero 坚持使用 Win64 调用约定（其中 @TwoBytes 将通过 RCX 传递）的计划（Allen Bauer 在某处提到），此答案中提供的版本应该仍然可以在 x64 上运行。