使用 Prolog 求解 CNF

Question

在学习Prolog时，我尝试编写一个解决CNF问题的程序（性能不是问题），所以我最终得到了以下代码来解决 (!x||y||!z)&& (x||!y||z)&&(x||y||z)&&(!x||!y||z)：

vx(t).
vx(f).
vy(t).
vy(f).
vz(t).
vz(f).

x(X) :- X=t; \+ X=f.
y(Y) :- Y=t; \+ Y=f.
z(Z) :- Z=t; \+ Z=f.
nx(X) :- X=f; \+ X=t.
ny(Y) :- Y=f; \+ Y=t.
nz(Z) :- Z=f; \+ Z=t.

cnf :-
   (nx(X); y(Y); nz(Z)),
   (x(X); ny(Y); z(Z)),
   (x(X); y(Y); z(Z)),
   (nx(X); ny(Y); z(Z)),
   write(X), write(Y), write(Z).

有没有更简单直接的使用这种声明性语言解决 CNF 的方法？

Answer 1

考虑直接使用内置谓词true/0和false/0，并使用toplevel来显示结果（独立地，而不是后续的几个write/1 调用，考虑使用 format/2)：

boolean(true).
boolean(false).

cnf(X, Y, Z) :-
        maplist(boolean, [X,Y,Z]),
        (\+ X; Y ; \+ Z),
        (   X ; \+ Y ; Z),
        (   X ; Y ; Z),
        (   \+ X ; \+ Y ; Z).

示例：

?- cnf(X, Y, Z).
X = true,
Y = true,
Z = true .

编辑：正如 @repeat 所解释的，还请认真查看 CLP(B)：约束求解超过布尔值。

使用 CLP(B)，您可以将上面的整个程序编写为：

:- use_module(library(clpb)).

cnf(X, Y, Z) :-
        sat(~X + Y + ~Z),
        sat(X + ~Y + Z),
        sat(X + Y + Z),
        sat(~X + ~Y + Z).

请参阅@repeat 的答案以获取有关此内容的更多信息。

Answer 2

查找“精益定理证明者”（例如 leanTAP 或 leanCoP）用于 Prolog 中的简单、简短的定理证明。它们旨在充分利用 Prolog 功能。尽管像这样的证明器使用一阶逻辑，但 CNF 是其子集。 Prolog 也有专用的 SAT 求解器，例如这个。

Answer 3

使用clpb！

:- use_module(library(clpb)).

检查某个布尔表达式是否可满足，使用 sat/1：

% OP: "(!x||y||!z) && (x||!y||z) && (x||y||z) && (!x||!y||z)"
?- sat((~X + Y + ~Z)*(X + ~Y + Z)*(X + Y + Z)*(~X + ~Y + Z)).
sat(X=\=X*Y#Z).

还没有具体的解决方案...但是比我们开始使用的术语简单得多！

要获得具体的真值，请使用 labeling/1：

?- sat(X=\=X*Y#Z), labeling([X,Y,Z]).
   X = 0, Y = 0, Z = 1
;  X = 0, Y = 1, Z = 1
;  X = 1, Y = 0, Z = 0
;  X = 1, Y = 1, Z = 1.