CoCo 到 ANTLR 转换器中的表达式

Question

我正在一个实用程序中解析 CoCo/R 语法以自动化 CoCo -> ANTLR 翻译。核心 ANTLR 语法是：

rule '=' expression '.' ;

expression
     : term ('|' term)*
         -> ^( OR_EXPR term term* )
     ;
term
     : (factor (factor)*)? ;

factor
     : symbol
     | '(' expression ')'
         -> ^( GROUPED_EXPR expression )
     | '[' expression']'
         -> ^( OPTIONAL_EXPR expression)
     | '{' expression '}'
         -> ^( SEQUENCE_EXPR expression)
     ;

symbol
     : IF_ACTION
     | ID (ATTRIBUTES)?
     | STRINGLITERAL
     ;

我的问题是这样的结构：

CS = { ExternAliasDirective }
         { UsingDirective }
         EOF .

CS 结果是带有 OR_EXPR 节点的 AST，尽管没有“|”特点 实际上出现了。我确信这是由于定义 表达式，但我看不到任何其他方式来编写规则。

我确实对此进行了实验以解决歧义。

// explicitly test for the presence of an '|' character
expression
@init { bool ored = false; }
     : term {ored = (input.LT(1).Type == OR); } (OR term)*
         ->  {ored}? ^(OR_EXPR term term*)
         ->            ^(LIST term term*)

它确实有效，但这次黑客攻击让我更加坚信某些根本性的问题是错误的。

非常感谢任何提示。

Answer 1

您的规则：

expression
  : term ('|' term)*
      -> ^( OR_EXPR term term* )
  ;

始终导致重写规则创建根类型为 OR_EXPR 的树。您可以像这样创建“子重写规则”：

expression
  :  (term -> REWRITE_RULE_X) ('|' term -> ^(REWRITE_RULE_Y))*
  ;

为了解决语法中的歧义，最简单的方法是启用全局回溯，这可以在语法的 options { ... } 部分中完成。

一个快速演示：

grammar CocoR;

options {
  output=AST;
  backtrack=true;
}

tokens {
  RULE;
  GROUP;
  SEQUENCE;
  OPTIONAL;
  OR;
  ATOMS;
}

parse
  :  rule EOF -> rule
  ;

rule
  :  ID '=' expr* '.' -> ^(RULE ID expr*)
  ;

expr
  :  (a=atoms -> $a) ('|' b=atoms -> ^(OR $expr $b))*
  ;

atoms
  :  atom+ -> ^(ATOMS atom+)
  ;

atom
  :  ID
  |  '(' expr ')' -> ^(GROUP expr)
  |  '{' expr '}' -> ^(SEQUENCE expr)
  |  '[' expr ']' -> ^(OPTIONAL expr)
  ;

ID
  :  ('a'..'z' | 'A'..'Z') ('a'..'z' | 'A'..'Z' | '0'..'9')*
  ;

Space
  :  (' ' | '\t' | '\r' | '\n') {skip();}
  ;

使用输入：

CS = { ExternAliasDirective }
     { UsingDirective }
     EOF .

生成 AST：

，输入：

foo = a | b ({c} | d [e f]) .

生成：

测试此类：

import org.antlr.runtime.*;
import org.antlr.runtime.tree.*;
import org.antlr.stringtemplate.*;

public class Main {
    public static void main(String[] args) throws Exception {
        /*
        String source = 
                "CS = { ExternAliasDirective } \n" +
                "{ UsingDirective }            \n" + 
                "EOF .                           ";
        */
        String source = "foo = a | b ({c} | d [e f]) .";
        ANTLRStringStream in = new ANTLRStringStream(source);
        CocoRLexer lexer = new CocoRLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        CocoRParser parser = new CocoRParser(tokens);
        CocoRParser.parse_return returnValue = parser.parse();
        CommonTree tree = (CommonTree)returnValue.getTree();
        DOTTreeGenerator gen = new DOTTreeGenerator();
        StringTemplate st = gen.toDOT(tree);
        System.out.println(st);
    }
}

并使用该类生成的输出，我使用以下网站创建 AST 图像：< a href="http://graph.gafol.net/" rel="nofollow noreferrer">http://graph.gafol.net/

HTH

---

编辑

要考虑 OR 表达式，您可以尝试这样的操作（快速测试！）：

expr
  :  (a=atoms -> $a) ( ( '|' b=atoms -> ^(OR $expr $b)
                       | '|'         -> ^(OR $expr NOTHING)
                       )
                     )*
  ;

它将源：解析

foo = a | b | .

为以下 AST：

Answer 2

expression 的产生式明确表示它只能返回一个 OR_EXPR 节点。您可以尝试以下操作：

expression
     : 
     term
     |
     term ('|' term)+
         -> ^( OR_EXPR term term* )
     ;

再往下，您可以使用：

term
     : factor*;