聚合计数计数器

Question

很多时候，我发现自己使用 Tally[ ] 来计算出现次数，然后，一旦我放弃了原始列表，就必须将另一个列表的结果添加（并加入）到该计数器列表中。

这种情况通常发生在我计算配置、出现次数、进行一些离散统计等时。

因此，我为 Tally 聚合定义了一个非常简单但方便的函数：

aggTally[listUnTallied__List:{}, 
         listUnTallied1_List,
         listTallied_List] := 
 Join[Tally@Join[listUnTallied, listUnTallied1], listTallied] //. 
     {a___, {x_, p_}, b___, {x_, q_}, c___} -> {a, {x, p + q}, b, c};

这​​样

l = {x, y, z}; lt = Tally@l;
n = {x};
m = {x, y, t};

aggTally[n, {}]
  {{x, 1}}

aggTally[m, n, {}]
  {{x, 2}, {y, 1}, {t, 1}}

aggTally[m, n, lt]
  {{x, 3}, {y, 2}, {t, 1}, {z, 1}}

该函数有两个问题：

1）性能

Timing[Fold[aggTally[Range@#2, #1] &, {}, Range[100]];]
  {23.656, Null}
(* functional equivalent to *)
Timing[s = {}; j = 1; While[j < 100, s = aggTally[Range@j, s]; j++]]
  {23.047, Null}

2）它不验证最后一个参数是一个真实计数列表或空（但对我来说不太重要）

是否有一个简单，优雅，更快，更有效的解决方案？ （我知道这些要求太多，但愿望是免费的）

Answer 1

也许，这会满足您的需求？

aggTallyAlt[listUnTallied__List : {}, listUnTallied1_List, listTallied : {{_, _Integer} ...}] :=
{#[[1, 1]], Total@#[[All, 2]]} & /@ 
       GatherBy[Join[Tally@Join[listUnTallied, listUnTallied1], listTallied], First]

计时要好得多，并且对最后一个参数进行基于模式的检查。

编辑：

这是一个更快的版本：

aggTallyAlt1[listUnTallied__List : {}, listUnTallied1_List, listTallied : {{_, _Integer} ...}] :=
Transpose[{#[[All, 1, 1]], Total[#[[All, All, 2]], {2}]}] &@
   GatherBy[Join[Tally@Join[listUnTallied, listUnTallied1], listTallied], First]

它的计时：

In[39]:= Timing[Fold[aggTallyAlt1[Range@#2, #1] &, {}, Range[100]];]
Timing[s = {}; j = 1; While[j < 100, s = aggTallyAlt1[Range@j, s]; j++]]

Out[39]= {0.015, Null}

Out[40]= {0.016, Null}

Answer 2

以下解决方案只是对原始函数的一个小修改。它在使用 ReplaceRepeated 之前应用 Sort，因此可以使用不太通用的替换模式，从而使其速度更快：

aggTally[listUnTallied__List : {}, listUnTallied1_List, 
   listTallied : {{_, _Integer} ...}] := 
  Sort[Join[Tally@Join[listUnTallied, listUnTallied1], 
     listTallied]] //. {a___, {x_, p_}, {x_, q_}, c___} -> {a, {x, p + q}, c};

Answer 3

这是我迄今为止想出的最快的方法，(ab)使用 Sow 和 Reap 可用的标记：

aggTally5[untallied___List, tallied_List: {}] :=
  Last[Reap[
    Scan[((Sow[#2, #] &) @@@ Tally[#]) &, {untallied}];
    Sow[#2, #] & @@@ tallied;
    , _, {#, Total[#2]} &]]

不会赢得任何选美比赛，但这都是关于速度，对吧？ =)

Answer 4

如果您纯粹是象征性的，您可以尝试一些类似于

(Plus @@ Times @@@ Join[#1, #2] /. Plus -> List /. Times -> List) &

加入计数列表的操作。这是愚蠢的快，但返回的东西不是计数列表，所以它需要一些工作（之后它可能不再那么快了;)）。

编辑：所以我有一个工作版本：

aggT = Replace[(Plus @@ Times @@@ Join[#1, #2] 
                  /. Plus -> List 
                  /. Times[a_, b_] :> List[b, a]), 
                k_Symbol -> List[k, 1], {1}] &;

使用几个随机符号表我得到

a := Tally@b;
b := Table[f[RandomInteger@99 + 1], {i, 100}];

Timing[Fold[aggT[#1, #2] &, a, Table[a, {i, 100}]];]
--> {0.104954, Null}

这个版本只添加计数列表，不检查任何内容，仍然返回一些整数，并与 Leonid 的函数进行比较：

Timing[Fold[aggTallyAlt1[#2, #1] &, a, Table[b, {i, 100}]];]
--> {0.087039, Null}

它已经是几秒钟了慢一些:-(。

哦，好吧，不错的尝试。