SQL Server 的 printf

Question

Sql Server中有类似printf的函数吗？我想要与 RAISERROR 函数相同的功能，但我不想抛出错误或打印消息，而是想将其写入 varchar，因为我的 ERP 不允许我处理错误消息。

这是 SQL Server 2000。

RAISERROR 的实际工作示例：

declare @name varchar(10)
set @name = 'George'

RAISERROR ('Hello %s.', 10, 1, 'George')

打印 Hello George

我要查找的内容：

declare @name varchar(10), @message varchar(50)
set @name = 'George'

SET @message = printf('Hello %s.', 'George')
return @message

这将返回 Hello George

Answer 1

PRINT 只是 RAISERROR，严重性为 0。所以你可以使用。

declare @name varchar(10)
set @name = 'George'

RAISERROR ('Hello %s.', 0, 1, 'George') WITH NOWAIT

编辑以将其存储到变量中，您可以使用 xp_sprintf 扩展存储过程。

declare @name varchar(10)
set @name = 'George'

DECLARE @ret varchar(500)
exec master..xp_sprintf @ret OUTPUT, 'Hello %s.', @name
PRINT @ret

Answer 2

如果您的格式字符串数量有限，并且能够将它们添加到 sysmessages（通过 sp_addmessage)，您可以使用 FORMATMESSAGE：

与 RAISERROR 语句一样，FORMATMESSAGE 通过用提供的参数值替换消息中的占位符变量来编辑消息。有关错误消息中允许的占位符和编辑过程的详细信息，请参阅 RAISERROR。

---

下面是 SQL Server 2005 或更高版本的有效答案，但不幸的是，OP 正在寻找 SQL Server 2000 的解决方案：

---

它很丑陋，并且滥用 Try/Catch 和 RAISERROR ：

declare @message varchar(50)

begin try
    RAISERROR('Hello %s',16,1,'george')
end try
begin catch
    set @message = ERROR_MESSAGE()
end catch

print @message

Answer 3

从 SQL Server 2016 开始，formatmessage 和 raiserror 已进行扩展，使其几乎可以像 C 的 printf函数。第一个参数（以前必须是引用 sys.messages 中预定义消息的整数）现在可以是 printf 样式的格式字符串

select formatmessage(
    'This is a string %s and this is an integer %i%sand this is a string weirdly padded with spaces <<%7.3s>>%sand this is a hex representation of an integer %x',
    'foo',
    42,
    char(13) + char(10),
    'bar',
    char(13) + char(10),
    1337
);

/* output:
This is a string foo and this is an integer 42
and this is a string weirdly padded with spaces <<    bar>>
and this is a hex representation of an integer 539
*/

： 不隐式支持相同的格式，没有什么可以阻止您将 formatmessage 与此构造一起使用：

declare @errorMessage nvarchar(max) = formatmessage(
    'This is a string %s and this is an integer %i%sand this is a string weirdly padded with spaces <<%7.3s>>%sand this is a hex representation of an integer %x',
    'foo',
    42,
    char(13) + char(10),
    'bar',
    char(13) + char(10),
    1337
);

throw 50000, @errorMessage, 1;

/* output:
Msg 50000, Level 16, State 1, Line 21
This is a string foo and this is an integer 42
and this is a string weirdly padded with spaces <<    bar>>
and this is a hex representation of an integer 539
*/

Answer 4

下面是一个使用 sql_variant 数据类型的简单 printf 过程。不幸的是，它仅适用于 SQL Server 2008 及更高版本。

CREATE PROCEDURE dbo.printf
  @string nvarchar(max),
  @p1 sql_variant = null,
  @p2 sql_variant = null,
  @p3 sql_variant = null
AS
BEGIN
  declare @str nvarchar(200), @pos int, @type char(1)
  select @str = @string, @pos = 0

  --- @p1
  set @pos = CHARINDEX('%', @str, @pos)
  if @pos > 0 and substring(@str, @pos, 2) = '%%'
    set @str = stuff(@str, @pos, 2, coalesce(cast(@p1 as nvarchar(100)),'<null>')) 

  --- @p2
  set @pos = CHARINDEX('%', @str, @pos)
  if @pos > 0 and substring(@str, @pos, 2) = '%%'
    set @str = stuff(@str, @pos, 2, coalesce(cast(@p2 as nvarchar(100)),'<null>')) 

  --- @p3
  set @pos = CHARINDEX('%', @str, @pos)
  if @pos > 0 and substring(@str, @pos, 2) = '%%'
    set @str = stuff(@str, @pos, 2, coalesce(cast(@p3 as nvarchar(100)),'<null>')) 

  print @str
END

以下是示例调用：

exec dbo.printf 'Hello %%', 'World'
exec dbo.printf 'Hello %%. Today is %% of the month', 'World', 28
declare @dd datetime; set @dd = getDate()
exec dbo.printf 'Hello %%. Today''s date is %%', 'World', @dd

Answer 5

如果您希望在变量中存储一些消息，那么 SET 应该足以让您处理对吧？除非我不清楚这个问题。

SET @varcharVariable = 'message text';