在VB.NET中使用鼠标滚轮和Ctrl控制WinForms的缩放级别

Question

如果我有一个 winform，我可以知道如何使用 Ctrl + 鼠标滚轮控制应用程序中字体的缩放级别（显然还有应用程序窗口本身）？我看到滚轮事件中有一个 Delta，但不确定它是如何工作的。有没有我可以查看的代码示例？

Answer 1

我怀疑你可以测试：

(VB.NET):(

If (ModifierKeys And Keys.Control) = Keys.Control Then

C#):

if( (ModifierKeys  & Keys.Control) == Keys.Control )

来检查控制键是否按下。

Answer 2

您必须处理 KeyDown 和 KeyUp 事件以确定 Ctrl 键是否为被压制。该值应该存储在类级别，因为除了 KeyDown 和 KeyUp 事件之外，其他子例程也会使用它。

然后编写代码来处理表单的 MouseWheel 事件。向下滚动（朝您的方向）会导致 MouseEventArgs 的Delta 属性。向上滚动显然是相反的。目前Delta属性的值始终是120。

微软给出这个值的原因如下：

目前，120 是一个制动器的标准值。如果引入更高分辨率的鼠标，WHEEL_DELTA 的定义可能会变小。大多数应用程序应该检查正值或负值，而不是总计。

在您的上下文中，您只需检查 Delta 的符号并执行操作。

以下是实现基本“缩放”功能的示例代码：

Public Class Form1
    Enum ZoomDirection
        None
        Up
        Down
    End Enum

    Dim CtrlIsDown As Boolean
    Dim ZoomValue As Integer

    Sub New()

        ' This call is required by the designer.
        InitializeComponent()

        ' Add any initialization after the InitializeComponent() call.
        ZoomValue = 100
    End Sub

    Private Sub Form1_KeyDown_KeyUp(ByVal sender As Object, _
                                    ByVal e As KeyEventArgs) _
                Handles Me.KeyDown, Me.KeyUp

        CtrlIsDown = e.Control
    End Sub

    Private Sub Form1_MouseWheel(ByVal sender As Object, 
                                 ByVal e As MouseEventArgs) _
                Handles Me.MouseWheel

        'check if control is being held down
        If CtrlIsDown Then
            'evaluate the delta's sign and call the appropriate zoom command
            Select Case Math.Sign(e.Delta)
                Case Is < 0
                    Zoom(ZoomDirection.Down)
                Case Is > 0
                    Zoom(ZoomDirection.Up)
                Case Else
                    Zoom(ZoomDirection.None)
            End Select
        End If
    End Sub

    Private Sub Zoom(ByVal direction As ZoomDirection)
        'change the zoom value based on the direction passed

        Select Case direction
            Case ZoomDirection.Up
                ZoomValue += 1
            Case ZoomDirection.Down
                ZoomValue -= 1
            Case Else
                'do nothing
        End Select

        Me.Text = ZoomValue.ToString()
    End Sub
End Class

请阅读以下内容以获取有关您的问题的更多信息：

1. MSDN：Control.KeyDown 事件
2. MSDN：Control.KeyUp 事件
3. MSDN：Control.MouseWheel 事件< /a>
4. MSDN ：MouseEventArgs类

Answer 3

对于 CrystalReportViewer1

只需放入 CrystalReportViewer1.Zoom(ZoomValue)
而不是子缩放中的 Me.Text = ZoomValue.ToString() 行