尝试在 Erlang 中组合列表时出现问题

Question

作为学习 Erlang 的练习，我正在尝试编写一个简单的数据库（来自 O'Reilly 的《Programming Erlang》）。

基本上我有一个像这样的元组列表：

Db1 = [{person1,charleston},{person2,charleston},{person3,chicago}].

我需要创建

db:match(charleston,Db1).

返回

[person1,person2]

的函数这是我编写的方法：

match(Element, Db) -> match(Element, Db, []).
match(_Element,[], Results) -> Results;
match(Element, [{Key,Value}|T], Results) ->
    case Value == Element of
        true -> match(Element, T, [Results,Key]);
        false -> match(Element,T,Results)
    end.

我得到的结果是这样的：

[[[],person1],person2]

我知道有一些方法可以将列表与列表结合起来。 erl 模块，但我试图绕过它，以了解有关该语言的更多信息。有什么想法我做错了吗？

Answer 1

你正在重新发明轮子。只需使用 列表理解：

match(X, Db) -> [P || {P, E} <- Db, E == X].

Answer 2

问题在于如何构建列表，请尝试以下操作：

case Value == Element of
    true -> match(Element, T, [Key|Results]);
    false -> match(Element,T,Results)
end.

• [A,B] 使用元素 A 和 B 构建一个新列表。
• [A|B] 将 A 添加到列表 B 之前。

Answer 3

直接编写代码的另一种方法是

match(_Value, []) -> [];
match(Value, [{Key,Value}|T]) ->
    [Key|match(Value, T)];
match(Value, [_|T]) ->
    match(Value, T).

@Little Bobby Tables 解决方案中的列表理解与此等效。