XQuery - 去掉标签但保留其文本

Question

如何在 XQuery 中删除一组标签但仍保留其文本？例如，如果我有：

<root>
    <childnode>This is <unwantedtag>some text</unwantedtag> that I need.</childnode>
</root>

如何去掉不需要的标签以获取：

<root>
    <childnode>This is some text that I need.</childnode>
</root>

实际上，我真正想要得到的只是文本，例如：

This is some text that I need.

当我执行以下操作时：

let $text := /root/childnode/text()

我得到：

This is  that I need.

它缺少 其中的一些文本 部分。

关于如何返回这是我需要的一些文本。有什么想法吗？

谢谢。

Answer 1

您感兴趣的不是子节点的字符串值（而不是文本节点序列或简化元素）？您可以从 fn:string 获取字符串值：

string(/root/childnode)

Answer 2

使用：

/*/childnode//text()

当在提供的 XML 文档上计算此 XQuery 时：

<root>
 <childnode>This is <unwantedtag>some text</unwantedtag> that I need.</childnode>
</root>

生成所需的正确结果：

This is some text that I need.

Answer 3

此 XQuery：

declare function local:copy($element as element()) {
   element {node-name($element)}
           {$element/@*,
            for $child in $element/node()
            return if ($child instance of element())
                   then local:match($child)
                   else $child
           }
};
declare function local:match($element as element()) {
   if ($element/self::unwantedtag)
   then for $child in $element/node()
        return if ($child instance of element())
               then local:match($child)
               else $child
   else local:copy($element)
};
local:copy(/*)

输出：

<root>
    <childnode>This is some text that I need.</childnode>
</root>