使用 awk 删除包含唯一第一个字段的行？

Question

希望仅打印具有重复第一个字段的行。例如，从看起来像这样的数据：

1 abcd
1 efgh
2 ijkl
3 mnop
4 qrst
4 uvwx

应该打印出：（

1 abcd
1 efgh
4 qrst
4 uvwx

仅供参考 - 我的数据中第一个字段并不总是 1 个字符长）

Answer 1

awk 'FNR==NR{a[$1]++;next}(a[$1] > 1)' ./infile ./infile

是的，你给它相同的文件作为输入两次。由于您事先不知道当前记录是否为 uniq，因此您在第一次传递时基于 $1 构建了一个数组，然后仅输出见过 $1< /code> 在第二遍中不止一次。

我确信有一些方法只需一次通过文件即可完成此操作，但我怀疑它们是否会那么“干净”

解释

1. FNR==NR：只有当awk时，这才是正确的 正在读取第一个文件。它本质上是测试看到的记录总数 (NR) 与当前文件中的输入记录 (FNR)。
2. a[$1]++：构建一个关联数组a，who的键是第一个字段（$1），who的值各加1看到它的时间。
3. next：如果达到此值，则忽略脚本的其余部分，从新的输入记录开始
4. (a[$1] > 1) 这只会在第二遍./infile，它只打印我们多次看到的第一个字段（$1）的记录。本质上，它是 if(a[$1] > 1){print $0}

概念证明的简写

$ cat ./infile
1 abcd
1 efgh
2 ijkl
3 mnop
4 qrst
4 uvwx

$ awk 'FNR==NR{a[$1]++;next}(a[$1] > 1)' ./infile ./infile
1 abcd
1 efgh
4 qrst
4 uvwx

Answer 2

下面是一些 awk 代码，可以执行您想要的操作，假设输入已按其第一个字段进行分组（如 uniq 也需要）：

BEGIN {f = ""; l = ""}
{
  if ($1 == f) {
    if (l != "") {
      print l
      l = ""
    }
    print $0
  } else {
    f = $1
    l = $0
  }
}

在此代码中，f 是前一个字段字段 1 和 l 的值是该组的第一行（如果已经打印出来则为空）。

Answer 3

BEGIN { IDLE = 0; DUP = 1; state = IDLE }

{ 
  if (state == IDLE) {
    if($1 == lasttime) {
       state = DUP
       print lastline
    } else state = IDLE
  } else {
    if($1 != lasttime)
        state = IDLE
  }
  if (state == DUP)
    print $0
  lasttime = $1
  lastline = $0
}

Answer 4

假设您在问题中显示的有序输入：

awk '$1 == prev {if (prevline) print prevline; print $0; prevline=""; next} {prev = $1; prevline=$0}' inputfile

该文件只需读取一次。

Answer 5

如果您可以使用 Ruby(1.9+)

#!/usr/bin/env ruby
hash = Hash.new{|h,k|h[k] = []}
File.open("file").each do |x|
  a,b=x.split(/\s+/,2)
  hash[a] << b
end
hash.each{|k,v| hash[k].each{|y| puts "#{k} #{y}" } if v.size>1 }

输出：

$ cat file
1 abcd
1 efgh
2 ijkl
3 mnop
4 qrst
4 uvwx
4 asdf
1 xzzz

$ ruby arrange.rb
1 abcd
1 efgh
1 xzzz
4 qrst
4 uvwx
4 asdf