使 VarToDoubleAsString 使用 Delphi 设置（而不是操作系统设置）

Question

当将包含字符串值的 Variant 分配给浮点变量时，Delphi 调用 VarToDoubleAsString 进行转换，该转换又使用操作系统设置的小数点和千位分隔符（通过 VarR8FromStr）。如果必须更改 SysUtils.DecimalSeparator 和 SysUtils.ThousandSeparator ，就会出现问题。例如，运行以下程序：

program VarStrToFloat;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Math;

function FormatFloatUsingDelphiSettings(Value: Extended): string;
begin
  Result := FormatFloat('#,##0.00', Value);
end;

procedure Test(const AMsg: string);
var
  r1, r2: Extended;
  s1, s2: string;
  v: Variant;
begin
  r1 := 5432.1;
  s1 := FormatFloatUsingDelphiSettings(r1);
  v := s1; // <== conversion uses OS settings
  r2 := v;
  s2 := FormatFloatUsingDelphiSettings(r2);

  Write(AMsg: 8, s1: 10, s2: 10, '  ');
  if SameValue(r1, r2) then
    Writeln('OK')
  else
    Writeln('FAIL');
end;

procedure SwapEm;
var
  tmp: Char;
begin
  tmp := DecimalSeparator;
  DecimalSeparator := ThousandSeparator;
  ThousandSeparator := tmp;
end;

begin
  Test('Default');
  SwapEm;
  Test('Changed');
  Readln;
end.

第一个测试工作正常，第二个测试失败。

有没有办法使 Variant 转换使用 SysUtils.DecimalSeparator 和 SysUtils.ThousandSeparator ？

Answer 1

您可以根据自己的喜好替换 varutils.pas 中的 VarR8FromStr 函数，VarToDoubleAsString 将使用它：

function MyConversion(const strIn: WideString; LCID: Integer; dwFlags: Longint;
    out dblOut: Double): HRESULT; stdcall;
const
  CResult: array [False..True] of HRESULT = (VAR_INVALIDARG, VAR_OK);
var
  s: string;
begin
  s := StringReplace(StrIn, ThousandSeparator, '', [rfReplaceAll]);
  Result := CResult[TryStrToFloat(s, dblOut)];
end;

[...]

begin
  varutils.VarR8FromStr := MyConversion;
  [...]