向 CreateThread 传递参数

Question

我在调用 CreateThread 时将类引用作为参数传递给 ThreadProc 时遇到问题。这是一个示例程序，演示了我遇到的问题：

program test;

{$APPTYPE CONSOLE}

uses
  SysUtils, Windows, Dialogs;

type
    TBlah = class
        public
        fe: Integer;
    end;

function ThreadProc(param: Pointer) : DWORD;
begin
    ShowMessage(IntToStr(TBlah(param).fe));

    Result := 0;
end;

var
    tID: DWORD;
    handle: THandle;
    b: TBlah;
begin
    b := TBlah.Create;
    b.fe := 54;

    handle := CreateThread(nil, 0, @ThreadProc, Pointer(b), 0, tID);

    WaitForSingleObject(handle, INFINITE); 
end.

对 ShowMessage 的调用会弹出一个消息框，其中包含类似 245729105 的内容，而不是 54< /code> 正如我所料。

这可能只是对 Delphi 工作原理的一个基本误解，所以有人可以告诉我如何让它正常工作吗？

Answer 1

这里的问题是你的线程函数有错误的调用约定。您需要使用 stdcall 约定来声明它：

function ThreadProc(param: Pointer) : DWORD; stdcall;

---

话虽如此，它更惯用的做法是使用 TThread 后代来为您处理 OOP 到 C 函数返回 OOP 的转换。看起来像这样：

type
  TBlah = class(TThread)
  protected
    procedure Execute; override;
  public
    fe: Integer;
  end;

procedure TBlah.Execute;
begin
  ShowMessage(IntToStr(fe));
end;

var
  b: TBlah;

begin
  b := TBlah.Create(True);
  b.fe := 42;
  b.Start;
  b.WaitFor;
end.

顺便说一句，有人知道为什么 Windows.pas 将 TFNThreadStartRoutine 声明为 TFarProc 而不是正确类型化的函数指针吗？

Answer 2

您忘记了 stdcall 指令。

function ThreadProc(param: Pointer) : DWORD; stdcall;

Answer 3

并且不要使用 Pointer 转换：

handle := CreateThread(nil, 0, @ThreadProc, **Pointer**(b), 0, tID); 

b 已经是一个 Pointer （一个 Class，它是一个 <代码>对象 <代码>指针）