如何通过 NetConnection 将复杂类型中继到 FMS？

Question

我需要通过 NetConnection 将复杂类型对象（在 Flex 中标记为 RemoteClass）发送到其他客户端。

[RemoteClass]
public class ComplexType
{
    public var _someString:String;
    public var _someInt:int;
}

...并使用...

_nc = new NetConnection();
_nc.connect("rtmp://localhost/echo/");
_nc.addEventListener(NetStatusEvent.NET_STATUS, _onNetStatus);              
_nc.client = {};
_nc.client.echoCallback = _echoCallback;

var dto:ComplexType = new ComplexType();
dto._someInt = 4;
dto._someString = "abrakadabra";                    
_nc.call("echo", null, dto);

但是，服务器端的回调函数似乎不理解强类型对象并发送回以下内容：

private function _echoCallback(...args):void
{
    trace(ObjectUtil.toString(args));
    /*

    (Array)#0
      [0] (Object)#1
         _someInt = 4
         _someString = "abrakadabra"

    */
}

服务器端看起来像这样：

application.onAppStart = function () {
    trace("Application.onAppStart > application started");

    Client.prototype.echo = function (complexType /*ComplexType*/) {
        trace("Client.echo > calling echo");        
        application.broadcastMsg("echoCallback", complexType);
    }
}

有没有办法通过 NetConnection 中继强类型对象？

EDIT1：添加带有 ObjectUtil.toString() 输出的回调函数源代码

Answer 1

您需要将 alias 属性添加到 [RemoteClass] 注释中：

[RemoteClass(alias="my.unique.Class")]

这应该将匿名对象更改为 AMF 中的类型化对象。

Answer 2

用于发送用途：

var ba:ByteArray = new ByteArray();
ba.writeObject(dto);

_nc.call("echo", null, ba);

用于接收：

private function _echoCallback(ba:ByteArray):void
{
    var dto:ComplexType = ba.readObject() as ComplexType;

    trace(ObjectUtil.toString(dto));

    /*
    (ComplexType)#0
      _someInt = 4
      _someString = "abrakadabra"
    */
}

太棒了！！！！