使用 XSLT/XML 生成 HTML 标签的样式？ （xsl：属性集）

Question

好吧，这是一个艰难的小时左右...我在生成不同宽度的表格单元格时遇到了困难。我使用 XML/XSLT 输出 HTML，因此宽度基本上以 XML 格式存储：

<size>
<width1>5</width1>
<width2>4</width2>
<width3>7</width3>
</size>

使用 XSLT 的属性集，我应该有一个表格行和宽度分别为 5px、4px、7px 的单元格。然而，这样做的问题是 attribute-set 需要是 的子级才能工作。我不能这样做：（原谅缺少的 px）

<tr>
    <td>
        <xsl:attribute-set name="style">
            <xsl:attribute name="width"><xsl:value-of select="size/width1"/></xsl:attribute>
        </xsl:attribute-set>
    </td>
    <td>
        <xsl:attribute-set name="style">
            <xsl:attribute name="width"><xsl:value-of select="size/width2"/></xsl:attribute>
        </xsl:attribute-set>
    </td>
    <td>
        <xsl:attribute-set name="style">
            <xsl:attribute name="width"><xsl:value-of select="size/width3"/></xsl:attribute>
        </xsl:attribute-set>
    </td>
</tr>

有没有办法使用 XML 数据生成 html 标签来设置它们的样式？

Answer 1

您需要在 元素中添加 xsl:attribute，而不是 xsl:attribute-set：

<xsl:template match="size">
    <tr>
        <td>
            <xsl:attribute name="width">
                <xsl:value-of select="./width1"/>
            </xsl:attribute>
        </td>

        <td>
            <xsl:attribute name="width">
                <xsl:value-of select="./width2"/>
            </xsl:attribute>
        </td>

        <td>
            <xsl:attribute name="width">
                <xsl:value-of select="./width3"/>
            </xsl:attribute>
        </td>
    </tr>
</xsl:template>

Answer 2

更多 XSLT 样式：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" indent="yes"/>
    <xsl:template match="size">
        <table>
            <tr>
                <xsl:apply-templates/>
            </tr>
        </table>
    </xsl:template>
    <xsl:template match="size/*">
        <td style="width:{.}px;">
            <!-- Do stuff -->
        </td>
    </xsl:template>
</xsl:stylesheet>

应用于您的示例结果将是：

<table>
    <tr>
        <td style="width:5px;"></td>
        <td style="width:4px;"></td>
        <td style="width:7px;"></td>
    </tr>
</table>