使用 sed 删除两个模式之间的行（不包含）

Question

好吧，

我知道这是一个微不足道的问题，但是：我如何从两个已知模式/单词之间的文件中删除行：

模式1
垃圾
模式2

获得：

模式1
模式2

有谁知道学习 sed 的好（简单的写法！）资源吗？有很多清晰的例子吗？

Answer 1

sed -n '/pattern1/{p; :a; N; /pattern2/!ba; s/.*\n//}; p' inputfile

解释：

/pattern1/{         # if pattern1 is found
    p               # print it
    :a              # loop
        N           # and accumulate lines
    /pattern2/!ba   # until pattern2 is found
    s/.*\n//        # delete the part before pattern2
}
p                   # print the line (it's either pattern2 or it's outside the block)

编辑：

某些版本的sed必须用勺子喂养：

sed -n -e '/pattern1/{' -e 'p' -e ':a' -e 'N' -e '/pattern2/!ba' -e 's/.*\n//' -e '}' -e 'p' inputfile

Answer 2

这适用于 GNU 和 BSD sed：

sed '/pattern1/,/pattern2/{//!d;}' file

Answer 3

使用 awk 可以轻松完成此操作：

BEGIN { doPrint = 1; }
/pattern1/ { doPrint = 0; print $0; }
/pattern2/ { doPrint = 1; }
{ if (doPrint) print $0; }

我发现 sed 信息 是相当容易阅读，有很多例子。 awk 也是如此。

Answer 4

awk '/pattern1/{g=1;next}/pattern2/{g=0;next}g' file

Answer 5

这个 sed 代码也可以工作：

sed '/PATTERN1/,/PATTERN2/d' FILE

Answer 6

您还可以使用 Unix 文本编辑器 ed：

echo '
pattern1
garbage
pattern2
' > test.txt

cat <<-'EOF' | sed -e 's/^ *//' -e 's/ *$//' | ed -s test.txt &>/dev/null
  H
  /pattern1/+1,/pattern2/-1d
  wq
EOF

有关详细信息，请参阅：使用 ed 文本编辑文件脚本编辑器