松开“分配给过程变量的本地过程/函数”优雅地限制

Question

考虑以下测试用例：

{ CompilerVersion = 21 }
procedure Global();

  procedure Local();
  begin
  end;

type
  TProcedure = procedure ();
var
  Proc: TProcedure;
begin
  Proc := Local;  { E2094 Local procedure/function 'Local' assigned to procedure variable }
end;

在第 13 行，编译器发出错误级别的消息，禁止此类本地过程使用的所有情况。 “官方”解决方案是将 Local 符号提升到外部范围（即：使其成为 Global 的同级），这会对代码“结构化”产生负面影响。

---

我正在寻找以最优雅的方式规避它的方法，最好是让编译器发出警告级别的消息。

Answer 1

最好的选择是使用新的匿名方法功能将其声明为对过程的引用，然后您可以很好地封装所有内容。

type
  TProc = reference to procedure;

procedure Outer;
var
  Local: TProc;
begin
  Local := procedure
    begin
      DoStuff;
    end;
  Local;
end;

这解决了 Mason 通过捕获匿名函数本地的任何变量来描述的问题。

Answer 2

这就是为什么你不能这样做：

type
  TProcedure = procedure ();

function Global(): TProcedure;
var
  localint: integer;

  procedure Local();
  begin
    localint := localint + 5;
  end;

begin
  result := Local;
end;

本地过程可以访问外部例程的变量范围。不过，这些变量是在堆栈上声明的，一旦外部过程返回，这些变量就会变得无效。

但是，如果您使用的是 CompilerVersion 21 (Delphi 2010)，则您将获得 匿名方法可用，它应该能够执行您正在寻找的操作；你只需要稍微不同的语法。

Answer 3

如果确实需要在 D7 或更早版本中使用本地过程，可以使用此技巧：

procedure GlobalProc;
var t,maxx:integer; itr,flag1,flag2:boolean; iterat10n:pointer;
    //Local procs:
    procedure iterat10n_01;begin {code #1 here} end;
    procedure iterat10n_10;begin {code #2 here} end;
    procedure iterat10n_11;begin {code #1+#2 here} end;
begin
    //...
    t:=ord(flag2)*$10 or ord(flag1);
    if t=$11 then iterat10n:=@iterat10n_11
      else if t=$10 then iterat10n:=@iterat10n_10
        else if t=$01 then iterat10n:=@iterat10n_01
          else iterat10n:=nil;
    itr:=(iterat10n<>nil);
    //...
    for t:=1 to maxx do begin
        //...
        if(itr)then asm
            push ebp;
            call iterat10n;
            pop ecx;
        end;
        //...
    end;
    //...
end;

但是问题是地址寄存器在不同的机器上可能有所不同 - 因此需要使用本地过程调用编写一些代码并通过断点查看哪些寄存器是在那里使用......

是的 - 在大多数实际生产情况下，这个技巧只是某种缓解措施。

Answer 4

作为记录，我自制的闭包：

{ this type looks "leaked" }
type TFunction = function (): Integer;

function MyFunction(): TFunction;

  {$J+ move it outside the stack segment!}
  const Answer: Integer = 42;

  function Local(): Integer;
  begin
    Result := Answer;
    { just some side effect }
    Answer := Answer + Answer div 2;
  end;

begin
  Result := @Local;
end;


procedure TForm1.FormClick(Sender: TObject);
var
  Func: TFunction;
  N: Integer;
begin
  { unfolded for clarity }
  Func := MyFunction();
  N := Func();
  ShowMessageFmt('Answer: %d', [N]);
end;