Flash 播放器在循环播放电影时崩溃

Question

我正在尝试在 Flash 中实现某种幻灯片放映，它会循环播放大约 100 个 h.264 编码的电影。我正在使用 NetConnection 和 NetStream 类连接到本地硬盘上的文件（请参阅下面的代码）。

private function playMovie():void
{           
        var currentMovie:String = movies[index];
        index = (index + 1) % movies.length;

        netConnection = new NetConnection();
        netConnection.connect(null);

        if(netStream != null)
        {
            netStream.removeEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);         
            netStream = null;
        }

        netStream = new NetStream(netConnection);
        netStream.client = this;
        netStream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);

        stageVideo.attachNetStream(null);
        stageVideo.attachNetStream(netStream);

        netStream.play(currentMovie);
}

private function netStatusHandler(evt:NetStatusEvent):void
{
        if(evt.info.code == "NetStream.Play.Stop")
        {
            playMovie();
        }
}

public function onMetaData(e:Object):void 
{
        netStream.seek(int(e["duration"]));
}       
public function onXMPData (e:Object):void {}

问题是 Flashplayer 的内存使用量随着每部电影的增加而增加，当达到大约 1.3GB 时，它就会自行结束，没有任何错误消息。

我的问题显然是：我该如何解决这个问题？

Answer 1

您必须调用 NetConnection.close() 来释放资源，否则您的内存使用量将会增加，如您所见。不过，更好的做法是，在创建后保留相同的 NetConnection 和 NetStream 对象来播放不同的视频：

private function playMovie():void
{           
    var currentMovie:String = movies[index];
    index = (index + 1) % movies.length;

    if ( netConnection == null ) 
    {
        netConnection = new NetConnection();
        netConnection.connect(null);
    }

    if ( netStream == null )
    {
        netStream = new NetStream(netConnection);
        netStream.client = this;
        netStream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
        stageVideo.attachNetStream(netStream);
    }

    netStream.play(currentMovie);
}