在方案中生成 2-列表的列表

Question

(define cart-product
  (lambda (sos1 sos2)
    (if (null? sos1) '()
      (cons
       (cart-prod-sexpr (car sos1) sos2)
       (cart-product (cdr sos1) sos2)))))

(define cart-prod-sexpr
  (lambda (s sos)
    (if (null? sos) '()
        (cons
         (list s (car sos))
         (cart-prod-sexpr s (cdr sos))))))

调用 (cart-product '(qw) '(xy)) 会生成 (((qx) (qy)) ((wx) (wy)))。

我如何生成 ((qx) (qy) (wx) (wy)) 呢？

Answer 1

高阶函数获胜。 Haskell 的列表推导转换为 Scheme 以获得更好的解决方案：

; cart xs ys = [ [x,y] | x <- xs, y <- ys ]
(define (cart xs ys)
  (let ((f (lambda (x) (map (lambda (y) (list x y)) ys))))
    (concatenate (map f xs))))

(cart '(a b c) '(x y)) => ((a x) (a y) (b x) (b y) (c x) (c y))

它以 m*n (m = |xs|, n = |ys|) 运行。 concatenate 来自 SRFI-1。

Answer 2

未经测试。请注意，我定义的 append-list 过程实际上返回一个以 sos2 结尾的列表。这在这里是适当的（也是正确的做法），但并不普遍。

(define cart-product
  (lambda (sos1 sos2)
    (if (null? sos1) '()
      (append-list
       (cart-prod-sexpr (car sos1) sos2)
       (cart-product (cdr sos1) sos2)))))

(define cart-prod-sexpr
  (lambda (s sos)
    (if (null? sos) '()
        (cons
         (list s (car sos))
         (cart-prod-sexpr s (cdr sos))))))

(define append-list
  (lambda (sos1 sos2)
    (if (null? sos1) sos2
      (cons
        (car sos1)
        (append-list (cdr sos1) sos2)))))

请注意，如果列表的大小为 n，则需要时间 O(n³) 才能生成大小为 O(n²) 的列表。 使用常规 append 会花费 O(n⁴)。 我刚刚实现了常规 append 而没有实现它。如果你想获得 O(n²)，你必须更加聪明。就像这段未经测试的代码一样。

(define cart-product
  (lambda (sos1 sos2)
    (let cart-product-finish
      (lambda (list1-current list2-current answer-current)
        (if (null? list2-current)
          (if (null? list1-current)
             answer-current
             (cart-product-finish (car list1-current) sos2 answer-current))
          (cart-product-finish list1-current (car sos2)
            (cons (cons (cdr list1-current) (cdr list2-current)) answer-current))))
    (cart-product-finish list1 '() '())))

如果我遇到错误，想法是递归循环第一个和第二个元素的所有组合，每个组合都将 answer-current 替换为 cons ，又一个组合，然后是我们已经找到的其他所有组合。由于尾部调用优化，这应该是高效的。

Answer 3

从我的头顶上掉下来：

(define cart-product
  (lambda (sos1 sos2)
    (if (null? sos1) 
        '()
        (append
         (cart-prod-sexpr (car sos1) sos2)
         (cart-product (cdr sos1) sos2)))))

Answer 4

(reduce #'append 
           (mapcar #'(lambda(x)
                         (mapcar #'(lambda(y) 
                                       (list x y))
                          '(a b c))) 
           '(1 2 3)))

=> ((1 A) (1 B) (1 C) (2 A) (2 B) (2 C) (3 A) (3 B) (3 C))

[注：解为对于Common Lisp（CLisp）而不是Scheme，但我认为它在Scheme中应该非常相似]

外部（reduce #'append）用于替换（concatenate（map），如knivil在解决方案中给出的

但是，我不确定如何与其他解决方案相比，我的解决方案在性能参数上有所提高，有人可以对此发表评论吗？

Answer 5

这只是同一问题的不同解决方案。我认为这很容易理解，也许会对某人有所帮助。

(define (cart-product l1 l2)
  (define (cart-product-helper l1 l2 org_l2)
    (cond
      ((and (null? l1)) `())
      ((null? l2) (cart-product-helper (cdr l1) org_l2 org_l2))
      (else (cons (cons (car l1) (car l2)) (cart-product-helper l1 (cdr l2) org_l2)))
    )
  )
  (cart-product-helper l1 l2 l2)
)