使用宏在Word文档中查找不同格式的文本块

Question

我正在努力在 Microsoft Word (2007) 中为包含如下文本的文档创建宏：

(1) 粗体标题。 普通文本。

对于此文本，我想对该文本的第一部分 - (1) 粗体标题。 执行一些转换。

而“(1)”和“粗体标题”。具有一致的风格（粗体和 Arial），两者之间的空格没有（它是 Times New Roman，非粗体）。

我认为搜索以下内容是可行的，没有任何格式限制。

"^13(\([0-9]@\)) (?@)."

不幸的是，也存在文本如下所示的情况：

(1) 普通文本。

对于这样的块，我想完全跳过文本。

不幸的是，我的通配符搜索也会找到这些实例，除非我可以通过字体样式限制它。

如果我可以规范第一种情况下的空格，那么我可以在通配符搜索中添加字体限制以获取正确的内容。

.Text = "^13(\([0-9]@\)) (?@)."
.Font.Name = "Arial"
.Font.Size = 9
.Font.Bold = True

但是，我需要能够在搜索中抓取两个不同格式的项目来标准化该空间，但根据我有限的 VBA 知识，这似乎是不可能的。

有没有办法在Word宏中查找不同格式的文本？

谢谢！

Answer 1

我想知道这样的东西是否适合：

Dim s As Range
Dim wd As Range
Dim BoldHead As Boolean
Dim doc As Document

Set doc = Word.Documents("Doc2.doc")

For Each s In doc.Sentences
    If s.Words(1).Bold = True Then
        BoldHead = True
        For Each wd In s.Words
            If Trim(wd) <> vbNullString _
                And wd <> "." _
                And wd.Bold = False Then
                BoldHead = False
            End If
        Next
        If BoldHead Then
            Debug.Print s
        End If
    End If
Next

请注意，Word 有一个非常讨厌的习惯，即不计算数字，它认为它们是自动的。

Answer 2

Remou 的答案正是我所需要的，但由于 StackOverflow 是一个很棒的资源，因此我最终针对我们的特定情况对其进行了调整：

特别是，文本位于段落的第一句话内。不幸的是，这似乎并没有涵盖我们所有的情况，但它抓住了大多数情况，并让用户大部分到达那里。

（下面的一些评论包含在我发现的外部资源中，因此它们是否真的有必要值得怀疑，但是......它有效。）

' Do our bold heading replacements
Dim s As Range, p As Paragraph
Dim wd As Range
Dim BoldHead As Boolean
Dim doc As Document

Set doc = ActiveDocument

For Each p In doc.Paragraphs
    Set s = p.Range.Sentences(1)
    If s.Words(1).Bold = True And s.Words(1).Characters(1) = "(" Then
        BoldHead = True
        For Each wd In s.Words
            If Trim(wd) <> vbNullString _
                And wd <> "." _
                And wd.Bold = False Then
                BoldHead = False
            End If
        Next
        If BoldHead Then
            With s.Find
                ' Clear all previously set formatting for Find dialog box.
                .ClearFormatting
                .Text = "(\([0-9]@\)) (?@)."

                ' Clear all previously set formatting for Replace dialog box.
                .Replacement.ClearFormatting
                .Replacement.Text = "\1 \2."
                .Replacement.Font.SmallCaps = True
                .Replacement.Font.Name = "Times New Roman"
                .Replacement.Font.Bold = False

                ' The following parameters must be set as follows to find only text formatted for the specified font.
                .Forward = True
                .Wrap = wdFindContinue
                .Format = True
                .MatchCase = False
                .MatchWholeWord = False
                .MatchWildcards = True
                .MatchSoundsLike = False
                .MatchAllWordForms = False

                .Execute Replace:=wdReplaceOne
            End With

            With s.Find
                ' Clear all previously set formatting for Find dialog box.
                .ClearFormatting
                .Text = "(\([0-9]@\)) "

                ' Clear all previously set formatting for Replace dialog box.
                .Replacement.ClearFormatting
                .Replacement.Text = "\1" & vbTab
                .Replacement.Font.SmallCaps = False
                .Replacement.Font.Name = "Arial"
                .Replacement.Font.Bold = True

                ' The following parameters must be set as follows to find only text formatted for the specified font.
                .Forward = True
                .Wrap = wdFindContinue
                .Format = True
                .MatchCase = False
                .MatchWholeWord = False
                .MatchWildcards = True
                .MatchSoundsLike = False
                .MatchAllWordForms = False

                .Execute Replace:=wdReplaceOne
            End With
        End If
    End If
Next