KRL：如果那么其他问题

Question

我正在尝试编写类似于 If、else if、else 语句的内容。然而，在线编译器给我带来了问题。

我通常用 jquery 编写代码，然后发出它......但这次我尝试以 KRL 方式执行此操作，但遇到了问题。

当我编写如下内容（在 Pre 和 Post 块之间）时，出现编译器错误：

if (someExpression) then { //做一些代码 } 别的 { //做一些代码 我知道

这是有原因的...但我需要有人向我解释...或者向我指出文档。

Answer 1

对于 KRL，通常最好有单独的规则来处理问题中描述的“if...then”和“else”情况。这只是因为它是一种规则语言；你必须改变你思考问题的方式，而不是通常的程序方式。

也就是说，迈克提出明确事件的建议通常是解决问题的最佳方法。下面是一个示例：

ruleset a163x47 {
  meta {
    name "If-then-else"
    description <<
      How to use explicit events to simulate if..then..else behavior in a ruleset.
    >>
    author "Steve Nay"
    logging off
  }
  dispatch { }
  global { }

  rule when_true {
    select when web pageview ".*"

    //Imagine we have an entity variable that tracks
    // whether the user is logged in or not
    if (ent:logged_in) then {
      notify("My app", "You are already logged in");
    }

    notfired {
      //This is the equivalent of an else block; we're sending
      // control to another rule.
      raise explicit event not_logged_in;
    }
  }

  rule when_false {
    select when explicit not_logged_in

    notify("My app", "You are not logged in");
  }
}

在这个简单的示例中，编写两个相同的规则也很容易，只是一个规则在 if 语句中包含一个 not，另一个规则在 if 语句中包含一个 not。没有。这实现了相同的目的：

if (not ent:logged_in) then {

在 Kynetx 文档。我也喜欢迈克在 Kynetx 应用一天。

Answer 2

您可以在 pre 块中使用三元运算符进行变量赋值，如 http://kynetxappaday.wordpress.com/2010/12/21/day-15-ternary-operators-or-conditional-expressions/

您还可以根据条件有条件地引发显式事件是否触发操作块，如 http://kynetxappaday.wordpress.com/2010/12/15/day-6-conditional-action-blocks-and-else-postludes/

Answer 3

以下是 Sam 发布的一些代码，解释了如何使用缺陷来模仿 ifthenelse 行为。这位天才的所有功劳都归功于萨姆·柯伦。这可能是您能得到的最佳答案。

ruleset a8x152 {
  meta {
    name "if then else"
    description <<
        Demonstrates the power of actions to enable 'else' in krl!
    >>
    author "Sam Curren"
    logging off
  }

  dispatch {
    // Deploy via bookmarklet
  }

  global {
    ifthenelse = defaction(cond, t, f){
      a = cond => t | f; 
      a();
    };
  }

  rule first_rule {
    select when pageview ".*" setting ()
    pre { 
        testcond = ent:counter % 2 == 1;
    }
    ifthenelse(
        testcond, 
        defaction(){notify("test","counter odd!");}, 
        defaction(){notify("test","counter even!");}
    );
    always {
        ent:counter += 1 from 1;
    }
  }
}