相当于 tcl 中的#define？

Question

tcl中有没有相当于C++#define的命令？我已经看到了使用 proc 函数重载来实现“定义”的方法，只是想知道是否有人知道更直接的方法

Answer 1

使用 interp alias 允许您在创建别名时使用 a 和 b 的内容：

interp alias {} foo_ab {} foo $a $b

如果您需要使用调用时的值，您需要一个辅助过程：

proc foo_ab args {
    global a b
    uplevel 1 [list foo $a $b {*}$args]
    # Or this in older Tcl: uplevel 1 [list foo $a $b] $args
}

在 8.5 中，也可以使用别名和 apply 编写：

interp alias {} foo_ab {} apply {args {
    global a b
    uplevel 1 [list foo $a $b {*}$args]
}}

在 8.6 中，您可以使用 tailcall 进一步优化code>：

interp alias {} foo_ab {} apply {args {
    global a b
    tailcall foo $a $b {*}$args
}}

您还可以使用其他一些更肮脏的技巧，如下所示：

interp alias {} foo_ab {} namespace inscope :: {foo $a $b}

虽然这不是特别快，但它确实适用于所有 Tcl 8.* 版本。

Answer 2

Tcl 有一种机制可以让您定义过程的别名在口译员中。

如果你

proc foo {one two three} {do something with $one $two $three}

发现你总是传递 $a 和 $b 作为前两个参数，你可以这样写：

interp alias {} foo_ab {} foo $a $b

现在你可以说：

foo_ab $d   ;# same as "foo $a $b $d"
foo_ab $e   ;# same as "foo $a $b $e"

示例：

proc foo {one two three} {puts [join [list $one $two $three] :]}
set a Hello
set b World
interp alias {} foo_ab {} foo $a $b
foo_ab example  ;# prints "Hello:World:example"

interp alias 命令中的空大括号只是表示当前的解释器。你可以和奴隶翻译一起做很多有趣的事情。

Answer 3

或者，您可以将 proc 定义为期望 d 和 e 作为具有默认值（例如空字符串）的输入参数，例如，

proc foo {a b c {d ""} {e ""} }.....

如果您要拥有未知数量的输入参数，您可以使用单词 args，这将创建一个包含 args 中每个值的列表，例如

   proc foo {a b c args } {
     foreach bar $args {
       #do whatever...
     }
   }

欢呼
布莱恩

Answer 4

如果“接收相同的参数”意味着您重复为 $a、$b 和 $c 传递相同的值，那么您的一种选择是使用全局变量而不是函数参数。在调用函数之前将值存储在其中，然后您的函数调用就会简化为 foo $d 等。