如何强制 FastCGI 将表单数据编码为 UTF-8，就像 CGI.pm 有选项一样？

Question

尝试在 FastCGI 下运行旧的 CGI 脚本。不带额外参数的打印会给出正确的输出： print $q->div( $q->param("text") )

但是当使用 CGI 方法的额外参数哈希打印时 print $q->div( {-id=>"id"}, $q->param("text") )，它会破坏 UTF-8 格式的数据 ('õäöüžš' ->; '

???????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????????一切都在普通 CGI 下完美运行（使用“-utf8”-flag）。

FastCGI 转换的示例脚本，称为 test.fcgi?text=õäöüžš 应该给出四个相等的块：

#!/usr/bin/perl -w --

use strict;
use CGI::Fast qw(:all);
use locale;
use utf8;

BEGIN {
        binmode(STDIN);                       # Form data
        binmode(STDOUT, ':encoding(UTF-8)');  # HTML
        binmode(STDERR, ':encoding(UTF-8)');  # Error messages
}

my ($q) = ();
my $test = "õäöüžš";

while ($q = new CGI::Fast) {

        print $q->header(-type=>"text/html", -charset=>"utf-8"), 
                $q->start_html(-encoding=>"utf-8");

        print "1: ",
                $q->div(  $q->param('text') ),
                "<br />",
                "2: ",
                $q->div( {-id=>"id"},  $q->param('text') ),
                "<br />",
                "3: ",
                $q->div(  $test ),
                "<br />",
                "4: ",
                $q->div( {-id=>"id"},  $test ),
        $q->end_html();

}

第一个块很好，第二个块损坏，第三个和第四个也很好：

普通的 CGI 示例，因为它给出了所有4正确的方法：

#!/usr/bin/perl -w --

use strict;
use CGI qw(:all -utf8);
use locale;
use utf8;

BEGIN {
        binmode(STDIN);                       # Form data
        binmode(STDOUT, ':encoding(UTF-8)');  # HTML
        binmode(STDERR, ':encoding(UTF-8)');  # Error messages
}

my ($q) = ();
my $test = "õäöüžš";
$q = new CGI;

        print $q->header(-type=>"text/html", -charset=>"utf-8"), 
                $q->start_html(-encoding=>"utf-8");

        print "1: ",
                $q->div(  $q->param('text') ),
                "<br />",
                "2: ",
                $q->div( {-id=>"id"},  $q->param('text') ),
                "<br />",
                "3: ",
                $q->div(  $test ),
                "<br />",
                "4: ",
                $q->div( {-id=>"id"},  $test ),
        $q->end_html();

在我看来，FastCGI表单数据没有utf8标志，我不明白，如何正确强制它？在 CGI.pm 下我声明为：

use CGI qw(:all -utf8);

但是 FastCGI 怎么样？

Answer 1

在 Git 2.27（2020 年第 2 季度）中，Gitweb 应该可以解决该问题。

请参阅 提交 2ecfcde（2020 年 3 月 29 日），作者：朱利安·穆蒂尼奥 (ju1m)。
^{（由 Junio C Hamano -- gitster -- 合并于 提交 7a8bb6d，2020 年 4 月 22 日）}

gitweb：修复 UTF-8 编码使用 CGI::Fast

^{签字人：朱利安·穆蒂尼奥}

FCGI 流是使用旧的流 API 实现的：TIEHANDLE，因此使用 binmode() 应用 PerlIO 层对它们没有影响。

此补丁中的解决方案是重新定义FCGI::Stream::PRINT函数以使用UTF-8作为输出编码，git_blob_plain( ) 和 git_snapshot() 仍必须以原始二进制模式输出。

此问题和解决方案早在 2012 年就已报告过：

• Git 邮件列表："作为 FCGI 运行的 Gitweb 不会以 UTF-8 打印其输出"
• 这个页面

Answer 2

我会这样做：

use strict;
use CGI;
CGI->compile();
use CGI::Fast;
use utf8;
while (new CGI::Fast) {
    $CGI::PARAM_UTF8=1;# may be this????
    my $q =CGI->new;
    #rest of the code should work
}

Answer 3

1) CGI::Fast 是 CGI.pm，因此您可以指定相同的导入参数。

use CGI::Fast (-utf8);

2) FCGI 流是使用旧的流 API 实现的，TIEHANDLE。使用 binmode() 应用 PerlIO 层没有任何效果。正确的解决方案是在输出数据之前对其进行编码，但如果这不是一个选项，我可以提供此热补丁：

#!/usr/bin/perl
use strict;
use warnings;
use utf8;

use CGI::Fast (-utf8);
use FCGI      ();
use Encode    ();

my $enc = Encode::find_encoding('UTF-8');
my $org = \&FCGI::Stream::PRINT;
no warnings 'redefine';
local *FCGI::Stream::PRINT = sub {
    my @OUTPUT = @_;
    for (my $i = 1; $i < @_; $i++) {
        $OUTPUT[$i] = $enc->encode($_[$i], Encode::FB_CROAK|Encode::LEAVE_SRC);
    }
    @_ = @OUTPUT;
    goto $org;
};

my $literal = "õäöüžš";

while (my $q = CGI::Fast->new) {
    print $q->header(-type => "text/html", -charset => "UTF-8"),
          $q->start_html(-encoding => "UTF-8"),
          $q->p("Text 1:" . $literal),
          $q->p("Text 2:" . $q->param('text')),
          $q->end_html;
}