将 Grails 应用程序配置注入到服务中

Question

我正在创建一个 grails 服务，它将通过 Java 库与第 3 方 REST API 进行交互。 Java 库需要通过 URL、用户名和密码来获取 REST API 的凭据。

我想将这些凭据存储在 configuration/Config.groovy 中，使它们可供服务使用，并确保在服务需要凭据之前可以使用这些凭据。

我很欣赏 grailsApplication.config 可用于控制器，并且通过服务的方法可以将相关配置值提供给服务，如下所示：

package example

class ExampleController {

    def exampleService

    def index = { }

    def process = {
        exampleService.setCredentials(grailsApplication.config.apiCredentials)
        exampleService.relevantMethod()
    }
}

package example

import com.example.ExampleApiClient;

class ExampleService {

    def credentials

    def setCredentials(credentials) {
        this.credentials = credentials
    }

    def relevantMethod() {

        def client = new ExampleApiClient(
            credentials.baseUrl,
            credentials.username,
            credentials.password
        )

        return client.action();
    }
}

我觉得这种方法略有缺陷因为它取决于调用 setCredentials() 的控制器。自动将凭证提供给服务将会更加可靠。

这两个选项是否可行（我目前对 grails 还不够熟悉）：

1. 在创建服务时将 grailsApplication.config.apiCredentials 注入到控制器中的服务中？

2. 在服务上提供某种形式的构造函数，允许在实例化时将凭据传递给服务？

将凭据注入到服务中是理想的选择。这怎么可能做到呢？

Answer 1

grailsApplication 对象在服务中可用，允许：

package example

import com.example.ExampleApiClient;

class ExampleService {

    def grailsApplication

    def relevantMethod() {

        def client = new ExampleApiClient(
            grailsApplication.config.apiCredentials.baseUrl
            grailsApplication.config.apiCredentials.username,
            grailsApplication.config.apiCredentials.password
        )

        return client.action();
    }
}

Answer 2

尽管 grailsApplication 可以注入到服务中，但我认为服务不必处理配置，因为它更难测试并破坏 单一责任原则。另一方面，Spring 可以以更健壮的方式处理配置和实例化。 Grails 在其文档中有专门的部分。

要使您的示例使用 Spring 工作，您应该在 resources.groovy 中将您的服务注册为 bean

// Resources.groovy
import com.example.ExampleApiClient

beans {
    // Defines your bean, with constructor params
    exampleApiClient ExampleApiClient, 'baseUrl', 'username', 'password'
}

然后您将能够将依赖项注入到您的服务中

class ExampleService {
    def exampleApiClient

    def relevantMethod(){
        exampleApiClient.action()
    }
}

此外，在您的 Config.groovy 中文件中，您可以使用 Grails 约定优于配置语法来覆盖任何 bean 属性：beans..:

// Config.groovy
...
beans.exampleApiClient.baseUrl = 'http://example.org'

Both Config.groovy并且resources.groovy支持不同的环境配置。

Answer 3

对于无法注入 grailsApplication bean 的上下文（如 Jon Cram 所描述，服务不是其中之一），例如位于 src/groovy 中的帮助器类，您可以使用 Holders 类：

def MyController {
   def myAction() {
      render grailsApplication == grails.util.Holders.grailsApplication
   }
}

Answer 4

最好的选择是（来自 grails 文档）：

1 - 使用Spring @Value 注释

import org.springframework.beans.factory.annotation.Value

class WidgetService {

    int area

    @Value('${widget.width}')
    int width

    def someServiceMethod() {
        // this method may use the width property...
    }
}

2 - 让您的类实现 GrailsConfigurationAware

import grails.config.Config
import grails.core.support.GrailsConfigurationAware

class WidgetService implements GrailsConfigurationAware {

    int area

    def someServiceMethod() {
        // this method may use the area property...
    }

    @Override
    void setConfiguration(Config co) {
        int width = co.getProperty('widget.width', Integer, 10)
        int height = co.getProperty('widget.height', Integer, 10)
        area = width * height
    }
}