.NET 中的非透明点击表单

Question

在.NET中，是否可以创建一个可以点击的非透明表单？我认为应该有某种 API 可以将鼠标点击传输到表单后面的窗口。哪一个？

Answer 1

要进行表单点击，您需要从 Windows API 中 P/Invoke 一些函数并设置表单的 扩展窗口样式。我任意选择用 VB.NET 来表示示例代码。如果这不是您的偏好，可以轻松将其转换为 C#。

从 GetWindowLong 函数 开始，您可以使用该函数将用于检索扩展窗口样式。

Public Const GWL_EXSTYLE As Integer = -20

<DllImport("user32.dll", CharSet:=CharSet.Auto)> _
Public Shared Function GetWindowLong(ByVal hWnd As IntPtr, _
                                     ByVal nIndex As Integer) As Integer
End Function

您还需要它的姊妹函数 SetWindowLong，指定附加的扩展窗口样式。

<DllImport("user32.dll", CharSet:=CharSet.Auto)> _
Public Shared Function SetWindowLong(ByVal hWnd As IntPtr, _
                                     ByVal nIndex As Integer, _
                                     ByVal dsNewLong As Integer) As Integer
End Function

以及需要设置的扩展窗口样式的常量：

Public Const WS_EX_TRANSPARENT As Integer = &H20

现在要使用所有这些，您可以覆盖表单的 OnLoad 方法 并添加以下行：

Protected Overrides Sub OnLoad(ByVal e As System.EventArgs)
   ''# Call the base class implementation
   MyBase.OnLoad(e)

   ''# Grab the current extended style information for this form
   Dim initialStyles As Integer = GetWindowLong(Me.Handle, GWL_EXSTYLE)

   ''# Add the transparent extended window style
   Dim newStyles As Integer = initialStyles Or WS_EX_TRANSPARENT

   ''# Update the form's extended window styles
   SetWindowLong(Me.Handle, GWL_EXSTYLE, newStyles)
End Sub

当然，请注意，用户现在不可能与表单上的元素进行交互，并且极 > 他们很难关闭它。仔细考虑这是否真的是您想要做的。