Ada 字符串连接

Question

我有一个函数，它返回特定项目的字符串，我需要多次调用该函数并将这些字符串合并为一个。组合后的字符串是有界的。我已确保在初始化时填充空格字符，但我不断收到“长度检查失败”错误。我在这里做错了什么基本的事情吗？

FOR I IN 1..Collection.Size LOOP  
    Combined_String :=  combined_string & Tostring(Collection.Book(I));  
END LOOP;

Answer 1

Unbounded_String 可能是最简单的方法：

with Ada.Strings.Unbounded;
use Ada.Strings.unbounded;

   ...

Temp_Unbounded_String : Unbounded_String;  -- Is empty by default.

   ...

for I in 1 .. Collection.Size loop
   Append(Temp_Unbounded_String, ToString(Collection.Book(I));
end loop;

如果您需要将结果放入固定长度的标准字符串中：

declare
   Temp_String : constant String := To_String(Temp_Unbounded_String);
begin
   -- Beware! If the length of the Temp_String is greater than that of the
   -- fixed-length string, a Constraint_Error will be raised.  Some verification
   -- of source and target string lengths must be performed!
   Combined_String(Temp_String'Range) := Temp_String;
end;

或者，您可以使用 Ada.Strings.Fixed Move() 过程将 Unbounded_String 放入目标固定长度字符串中：

Ada.Strings.Fixed.Move(To_String(Temp_Unbounded_String), Combined_String);

在这种情况下，如果源字符串如果“太长”，则默认会引发 Length_Error 异常。 Move() 还有其他参数可以修改这种情况下的行为，请参阅 移动 了解更多详细信息。

Answer 2

我知道这是一个古老的问题，但现在 Ada 2012 已经出版了，我想我应该分享一个我一直在使用的习语……

declare
  function Concatenate(i: Collection'index)
  is
    (tostring(Collection(i) &
      if (i = Collection'last) then
        ("")
      else
        (Concatenate(i+1))
    );

  s: string := Concatenate(Collection'first);
begin
  Put_Line(s);
end;

我凭空打字，所以它会充满拼写错误；如果您希望它在空集合上工作，您需要调整逻辑（应该是显而易见的）。

Ada 2012的表情功能太棒了！

Answer 3

为了分配Combined_String，您必须立即分配完整的正确长度。您无法“构建”字符串并在 Ada 中以这种方式分配它。

在没有看到其余代码的情况下，我认为 Ada.Strings.Unbounded 可能是您应该使用的。

Answer 4

当您可以使用尺寸完美的数组和字符串时，Ada 效果最佳。这对于 99% 的字符串使用都非常有效，但是当您需要从其他东西逐步构建字符串时，就会出现问题。

鉴于此，我真的很想知道为什么您需要该组合字符串。

如果您确实需要这样的功能，我知道有两种好方法可以实现。第一种是使用 Ada.Strings.Unbounded 中的“无界”（动态大小）字符串，正如 Dave 和 Marc C 所建议的那样。

另一种是使用一些函数式编程（在本例中为递归）来创建固定字符串。例如：

function Combined_String (String_Collection : in String_Collection_Type) return String is
begin
    if String_Collection'length = 1 then 
        return String_Collection(String_Collection'first);
    end if;    
    return String_Collection(String_Collection'first) & 
           Combined_String (String_Collection'first + 1 .. String_Collection'last);
end Combined_String;

我不知道你使用的 Collection 类型是什么，所以我做了一些猜测。特别是，我假设它是一个不受约束的固定字符串数组。如果不是，您将需要将上面的一些代码替换为容器用来返回其边界、访问元素和执行切片的代码。

Answer 5

来自 AdaPower.com：

function Next_Line(File : in Ada.Text_IO.File_Type :=
   Ada.Text_Io.Standard_Input) return String is
   Answer : String(1..256);
   Last   : Natural;
begin
   Ada.Text_IO.Get_Line(File => File,
      Item => Answer,
      Last => Last);
   if Last = Answer'Last then
      return Answer & Next_Line(File);
   else
      return Answer(1..Last);
   end if;
end Next_Line;

如您所见，此方法从其读取的文件中构建一个无限*长度的字符串（使用 Get_Line）。因此，为了保留您所拥有的内容，您需要做的是：

function Combined_String (String_Collection : in String_Collection_Type)
                   Return String is      
begin
    if String_Collection'length = 1 then 
        Return String_Collection(String_Collection'First).All;
    end if;

      Recursion:
      Declare
         Data : String:= String_Collection(String_Collection'First).All;
         SubType Constraint is Positive Range
           Positive'Succ(String_Collection'First)..String_Collection'Last;
      Begin
         Return Data & Combined_String( String_Collection(Constraint'Range) );
      End Recursion;
end Combined_String;

假设 String_Collection 定义为：

 Type String_Collection is Array (Positive Range <>) of Access String;

*实际上受 Integer'Range、IIRC 限制